Guia de início rápido: implantar a Pesquisa de IA do Azure usando o Bicep

Nota

O Pesquisa de IA do Azure está disponível através do portal Azure, APIs REST e SDKs do Azure. Também sustenta o Foundry IQ, a camada de conhecimento gerida que transforma conteúdos empresariais em bases de conhecimento reutilizáveis e conscientes de permissões para agentes no portal Microsoft Foundry.

Neste quickstart, use um ficheiro Bicep para implementar um serviço Pesquisa de IA do Azure no portal Azure.

O Bicep é uma linguagem específica do domínio que utiliza sintaxe declarativa para implementar recursos do Azure. Fornece sintaxe concisa, segurança de tipos fiável e suporte para reutilização de código. O Bicep oferece a melhor experiência de criação para suas soluções de infraestrutura como código no Azure.

A implementação utiliza apenas as propriedades incluídas no modelo. Se precisar de mais personalização, como configurar a segurança da rede, pode atualizar o serviço como uma tarefa pós-implementação. Para personalizar um serviço existente com o menor número de etapas, use a CLI do Azure ou o Azure PowerShell. Se estiver a avaliar funcionalidades de pré-visualização, use a API de Gestão REST.

Gorjeta

Para um modelo alternativo de Bicep que implementa o Pesquisa de IA do Azure com um indexador pré-configurado para o Cosmos DB for NoSQL, consulte a implementação do Bicep do Pesquisa de IA do Azure. Não há suporte para templates Bicep para operações no plano de dados do Pesquisa de IA do Azure, como criar um índice, mas podes adicionar um módulo que chame APIs REST. O exemplo inclui um módulo que cria um índice, um conector de fonte de dados e um indexador que atualiza do Cosmos DB em intervalos de cinco minutos.

Pré-requisitos

Se não tiver uma subscrição do Azure, crie uma conta gratuita antes de começar.

Revise o arquivo Bicep

Esta introdução rápida utiliza um ficheiro Bicep dos Azure Quickstart Templates.

@description('Service name must only contain lowercase letters, digits or dashes, cannot use dash as the first two or last one characters, cannot contain consecutive dashes, and is limited between 2 and 60 characters in length.')
@minLength(2)
@maxLength(60)
param name string

@allowed([
  'free'
  'basic'
  'standard'
  'standard2'
  'standard3'
  'storage_optimized_l1'
  'storage_optimized_l2'
])
@description('The pricing tier of the search service you want to create (for example, basic or standard).')
param sku string = 'standard'

@description('Replicas distribute search workloads across the service. You need at least two replicas to support high availability of query workloads (not applicable to the free tier).')
@minValue(1)
@maxValue(12)
param replicaCount int = 1

@description('Partitions allow for scaling of document count as well as faster indexing by sharding your index over multiple search units.')
@allowed([
  1
  2
  3
  4
  6
  12
])
param partitionCount int = 1

@description('Applicable only for SKUs set to standard3. You can set this property to enable a single, high density partition that allows up to 1000 indexes, which is much higher than the maximum indexes allowed for any other SKU.')
@allowed([
  'default'
  'highDensity'
])
param hostingMode string = 'default'

@description('Location for all resources.')
param location string = resourceGroup().location

resource search 'Microsoft.Search/searchServices@2020-08-01' = {
  name: name
  location: location
  sku: {
    name: sku
  }
  properties: {
    replicaCount: replicaCount
    partitionCount: partitionCount
    hostingMode: hostingMode
  }
}

O ficheiro Bicep define o seguinte recurso Azure:

Implantar o arquivo Bicep

  1. Salve o arquivo Bicep como main.bicep em seu computador local.

  2. Implante o arquivo Bicep usando a CLI do Azure ou o Azure PowerShell.

    az group create --name exampleRG --location eastus
az deployment group create --resource-group exampleRG --template-file main.bicep --parameters serviceName=<service-name>

    Nota

    Substitua <service-name> pelo nome do serviço de Pesquisa. O nome do serviço deve conter apenas letras minúsculas, dígitos ou traços. Você não pode usar um traço como os dois primeiros caracteres ou o último caractere. O nome tem um comprimento mínimo de 2 caracteres e um comprimento máximo de 60 caracteres.

    Quando a implantação for concluída, você verá uma mensagem indicando que a implantação foi bem-sucedida.

Rever os recursos implementados

Use o portal do Azure, a CLI do Azure ou o Azure PowerShell para listar os recursos implantados no grupo de recursos.

az resource list --resource-group exampleRG

Limpar recursos

O Pesquisa de IA do Azure é um recurso faturável. Se já não precisares, apaga-o da tua subscrição para evitar custos. Você pode usar o portal do Azure, a CLI do Azure ou o Azure PowerShell para excluir o grupo de recursos e seus recursos.

az group delete --name exampleRG

Conteúdo relacionado

Neste início rápido, você criou um serviço Pesquisa de IA do Azure usando um arquivo Bicep e, em seguida, validou a implantação. Para saber mais sobre o Pesquisa de IA do Azure e o Azure Resource Manager, consulte os seguintes artigos:

  • Última atualização a