Hızlı Başlangıç: Terraform kullanarak Azure AI Arama hizmeti dağıtma

Bu makalede Terraform kullanarak bir Azure Yapay Zeka Arama hizmeti oluşturmak için Terraform'un nasıl kullanılacağı gösterilmektedir.

Terraform , bulut altyapısının tanımlanmasını, önizlemesini ve dağıtımını sağlar. Terraform kullanarak HCL söz dizimlerini kullanarak yapılandırma dosyaları oluşturursunuz. HCL söz dizimi, Azure gibi bulut sağlayıcısını ve bulut altyapınızı oluşturan öğeleri belirtmenize olanak tanır. Yapılandırma dosyalarınızı oluşturduktan sonra, altyapı değişikliklerinizin dağıtılmadan önce önizlemesini görüntülemenizi sağlayan bir yürütme planı oluşturursunuz. Değişiklikleri doğruladıktan sonra, altyapıyı dağıtmak için yürütme planını uygularsınız.

Bu makalede şunları öğreneceksiniz:

Önkoşullar

• Terraform'u yükleme ve yapılandırma

Terraform kodunu uygulama

1. Örnek Terraform kodunu test etmek ve çalıştırmak için bir dizin oluşturun. Geçerli dizin yapın.

2. adlı main.tf bir dosya oluşturun ve aşağıdaki kodu ekleyin:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = random_pet.rg_name.id
     location = var.resource_group_location
   }
   
   resource "random_string" "azurerm_search_service_name" {
     length  = 25
     upper   = false
     numeric = false
     special = false
   }
   
   resource "azurerm_search_service" "search" {
     name                = random_string.azurerm_search_service_name.result
     resource_group_name = azurerm_resource_group.rg.name
     location            = azurerm_resource_group.rg.location
     sku                 = var.sku
     replica_count       = var.replica_count
     partition_count     = var.partition_count
   }
   

3. adlı outputs.tf bir dosya oluşturun ve aşağıdaki kodu ekleyin:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "azurerm_search_service_name" {
     value = azurerm_search_service.search.name
   }
   

4. adlı providers.tf bir dosya oluşturun ve aşağıdaki kodu ekleyin:

   terraform {
     required_version = ">=1.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   provider "azurerm" {
     features {}
   }
   

5. adlı variables.tf bir dosya oluşturun ve aşağıdaki kodu ekleyin:

   variable "resource_group_location" {
     type        = string
     description = "Location for all resources."
     default     = "eastus"
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
     default     = "rg"
   }
   
   variable "sku" {
     description = "The pricing tier of the search service you want to create (for example, basic or standard)."
     default     = "standard"
     type        = string
     validation {
       condition     = contains(["free", "basic", "standard", "standard2", "standard3", "storage_optimized_l1", "storage_optimized_l2"], var.sku)
       error_message = "The sku must be one of the following values: free, basic, standard, standard2, standard3, storage_optimized_l1, storage_optimized_l2."
     }
   }
   
   variable "replica_count" {
     type        = number
     description = "Replicas distribute search workloads across the service. You need at least two replicas to support high availability of query workloads (not applicable to the free tier)."
     default     = 1
     validation {
       condition     = var.replica_count >= 1 && var.replica_count <= 12
       error_message = "The replica_count must be between 1 and 12."
     }
   }
   
   variable "partition_count" {
     type        = number
     description = "Partitions allow for scaling of document count as well as faster indexing by sharding your index over multiple search units."
     default     = 1
     validation {
       condition     = contains([1, 2, 3, 4, 6, 12], var.partition_count)
       error_message = "The partition_count must be one of the following values: 1, 2, 3, 4, 6, 12."
     }
   }
   

Terraform'u başlatma

Terraform dağıtımını başlatmak için terraform init komutunu çalıştırın. Bu komut, Azure kaynaklarınızı yönetmek için gereken Azure sağlayıcısını indirir.

terraform init -upgrade

Önemli noktalar:

• -upgrade parametresi, gerekli sağlayıcı eklentilerini yapılandırmanın sürüm kısıtlamalarına uygun en yeni sürüme yükseltir.

Terraform yürütme planı oluşturun

Terraform planını çalıştırarak yürütme planı oluşturun.

terraform plan -out main.tfplan

Önemli noktalar:

• Komutu terraform plan bir yürütme planı oluşturur ama yürütmez. Bunun yerine, yapılandırma dosyalarınızda belirtilen yapılandırmayı oluşturmak için hangi eylemlerin gerekli olduğunu belirler. Bu düzen, gerçek kaynaklarda değişiklik yapmadan önce yürütme planının beklentilerinizle eşleşip eşleşmediğini doğrulamanızı sağlar.
• İsteğe bağlı -out parametresi, plan için bir çıkış dosyası belirtmenize olanak tanır. parametresinin -out kullanılması, gözden geçirdiğiniz planın tam olarak uygulanan plan olmasını sağlar.

Terraform yürütme planını uygula

Yürütme planını bulut altyapınıza uygulamak için terraform apply komutunu çalıştırın.

terraform apply main.tfplan

Önemli noktalar:

• Örnek terraform apply komutu, daha önce terraform plan -out main.tfplan komutunu çalıştırdığınızı varsayar.
• parametresi için -out farklı bir dosya adı belirttiyseniz, çağrısında terraform applyaynı dosya adını kullanın.
• parametresini -out kullanmadıysanız, parametresiz olarak çağırın terraform apply .

Sonuçları doğrulama

1. Azure Yapay Zeka Arama hizmetini oluşturduğunuz Azure kaynak adını alın.

   resource_group_name=$(terraform output -raw resource_group_name)
   

2. Azure AI Arama hizmeti adını alın.

   azurerm_search_service_name=$(terraform output -raw azurerm_search_service_name)
   

3. Azure AI Arama hizmetini göstermek için bu makalede oluşturduğunuz az search service show komutunu çalıştırın.

   az search service show --name $azurerm_search_service_name \
                          --resource-group $resource_group_name
   

Kaynakları temizleme

Terraform aracılığıyla oluşturulan kaynaklara artık ihtiyacınız kalmadığında aşağıdaki adımları uygulayın:

1. terraform plan'i çalıştırın ve destroy bayrağını belirtin.

   terraform plan -destroy -out main.destroy.tfplan
   

   Önemli noktalar:

   • Komutu terraform plan bir yürütme planı oluşturur ama yürütmez. Bunun yerine, yapılandırma dosyalarınızda belirtilen yapılandırmayı oluşturmak için hangi eylemlerin gerekli olduğunu belirler. Bu düzen, gerçek kaynaklarda değişiklik yapmadan önce yürütme planının beklentilerinizle eşleşip eşleşmediğini doğrulamanızı sağlar.
   • İsteğe bağlı -out parametresi, plan için bir çıkış dosyası belirtmenize olanak tanır. parametresinin -out kullanılması, gözden geçirdiğiniz planın tam olarak uygulanan plan olmasını sağlar.

2. Yürütme planını uygulamak için terraform apply komutunu çalıştırın.

   terraform apply main.destroy.tfplan
   

Azure'da Terraform sorunlarını giderme

Azure'da Terraform kullanırken karşılaşılan yaygın sorunları giderme

Sonraki adımlar