Exportar dados do VB6 para Excel

Anônima

Bom Dia a todos,

eu utilizo o Visual Basic 6 e estou precisando gerar um arquvio .xls (excel) a partir do datagrid.

Como eu posso fazer isso?

Atenciosamente,

Leandro Rodrigues MCP hotmail: *** O endereço de email foi removido para fins de privacidade *** skype: leandro_sr82

Pergunta bloqueada. Essa pergunta foi migrada da Comunidade de Suporte da Microsoft. É possível votar se é útil, mas não é possível adicionar comentários ou respostas ou seguir a pergunta.

0 comentários

Resposta aceita pelo autor da pergunta

Anônima

A resposta do colega Anderson é para VB.Net, não para VB6. Embora a lógica seja semelhante, no VB6 é um pouco mais difícil.

Criei este código e funcionou bem:

Private Sub ExportaExcel()

'Exporta os dados do DataGrid para o Excel

Dim oApp As Object ' Excel.Application

Dim oWkb As Object ' Excel.Workbook

Dim oWks As Object ' Excel.Worksheet

Dim l As Long

Dim c As Long

Set oApp = CreateObject("Excel.Application")

oApp.Visible = True

Set oWkb = oApp.Workbooks.Add

Set oWks = oWkb.Worksheets(1)

'Título das colunas

For c = 0 To Me.DataGrid1.Columns.Count - 1

oWks.Cells(1, c + 1).Value = Me.DataGrid1.Columns(c).Caption

Next c

'Conteúdo

l = 0

Me.DataGrid1.Row = l

Do While IsNumeric(Me.DataGrid1.Columns(0)) = True

For c = 0 To Me.DataGrid1.Columns.Count - 1

    oWks.Cells(l + 2, c + 1).Value = Me.DataGrid1.Columns(c).Value

Next c

l = l + 1

On Error Resume Next

Me.DataGrid1.Row = l

If Err &lt;&gt; 0 Then

    Err.Clear

    On Error GoTo 0

    Exit Do

End If

On Error GoTo 0

Loop

End Sub

Private Sub cmdExportarExcel_Click()

On Error GoTo ErrHandler

Call ExportaExcel

ExitHere:

Exit Sub

ErrHandler:

MsgBox Err.Description & vbCrLf & Err.Number & vbCrLf & Err.Source, vbCritical, "cmdExportarExcel_Click"

Resume ExitHere

End Sub

Luiz Cláudio Cosenza Vieira da Rocha - http://msmvps.com/blogs/officedev - IT Lab www.itlab.com.br

0 comentários

Exportar dados do VB6 para Excel

17 respostas adicionais