berekenen huursom in excel

Beste Bocculus,

Dank je wel voor je inbreng. Ik heb de formules ook doorgevoerd in mijn sheet. Ik kom een paar punten tegen;

-wanneer ik 2 boekingen in dezelfde maand heb wordt de Toeristenbelasting slechts op 1 regel toegepast.

-ik werk met een all-in huursom ( inclusief belastingen). Ik reken dus terug naar een basishuur ( om vervolgens de grondslag voor de heffing te hebben) BBV en Toeristenbelasting zijn 2 verschillende belastingen.

Ik ben er blij mee dat het in één regel mogelijk is in plaats van een tabel.

Moet wel zeggen dat JP er ook mee bezig is, hij heeft al gezorgd dat ik de uitgebreide formules per regel voor de tariefberekening huursom kwijt ben en kijkt momenteel ook naar de belastingen. Ik wil natuurlijk niet hebben dat jullie dubbel werk uitvoeren, maar mogelijk is het aanvulling op elkaar. Hopelijk lezen jullie beide mee.

Super bedankt in ieder geval.

Met vriendelijke groeten,

John van Gils

Beste John van Gils,

Waar JP koos voor een jaaroverzicht, heb ik een doorlopende lijst. Als je de rijen tot rij 10 op de gebruikelijke manier  blokkeert, dan houd je overzicht.

Uitgangspunt is, dat de aankomstdag geldt als eerste overnachting en dat de belasting wordt afgedragen in de maand volgend op de vertrekdatum. Het bedrag wordt naast de betreffende maand getoond.

Hoog tarief vanaf             15 dec 2020        1215      € 160,00

Laag tarief vanaf              01 mei 2020       0501      € 80,00

Schoonmaak                                                                    € 100,00

Toeristenbelasting                                                         9,50%

Verblijfsbelasting per 2 personen                            € 3,00

Bovenstaand schema in A2:D6. Het procentteken moet ook getypt worden.

Formules:

B2:  =DATUM(JAAR(VANDAAG());12;15)

C2:  =TEKST($B2;"mmdd")

B3:  =DATUM(JAAR(VANDAAG());5;1)

C3:  =TEKST($B3;"mmdd")

Kopteksten:

Kopteksten in rij 9 en 10. Kolomletters ter verduidelijking, kunnen worden verwijderd. Aankomst- en vertrekdatum en aantal gasten handmatig ingeven (kolommen A, B en C).

Formules:

D11:  =$B11-$A11

E11:  =ALS($D11>0;SOMPRODUCT((TEKST(RIJ(INDIRECT($A11&":"&($B11-1)));"mmdd")>=$C$3)*(TEKST(RIJ(INDIRECT($A11&":"&($B11-1)));"mmdd")<$C$2));0)

F11:  =ALS($D11>0;SOMPRODUCT(((TEKST(RIJ(INDIRECT($A11&":"&($B11-1)));"mmdd")>=$C$2)+(TEKST(RIJ(INDIRECT(A11&":"&(B11-1)));"mmdd")<$C$3)));0)

Maar eenvoudiger is natuurlijk F11:  =$D11-$E11

G11:  =GEHEEL(($C11+1)/2)*$D11

H11:  =ALS($D11>0;$E11*$D$3+$F11*$D$2+100;0)

I11:  =$G11*$D$6

J11:  =$H11+$I11

En voor de berekening van de toeristenbelasting:

Formules:

K11:  overslaan

L11:  =ALS(EN($D11>0;TEKST($B11;"mmjj")<>TEKST($B10;"mmjj"));$B11;"")

M11:  =SOMPRODUCT((TEKST($B$11:$B$300;"mmjj")=TEKST($L11;"mmjj"))*(($H$11:$H$300*$D$5)+$I$11:$I$300))

De formule in kolom G telt door, dus ook voor meer dan vier personen.

De toeristenbelasting verschijnt naast de betreffende maand en dient de volgende maand afgedragen te worden.

Groet,

Bocculus

Dag John,

Ik heb je mail goed ontvangen maar nog niet de tijd gehad om me verder te verdiepen.

Beste JP,

Ik heb  naar je gemaild, soms komt deze echter in de spambox.

met vriendelijke groet,

John van Gils