Una famiglia di software per fogli di calcolo Microsoft con strumenti per l'analisi, la creazione di grafici e la comunicazione dei dati.
Ciao Emiliano Li,
Ciao Norman, ho un piccolo problema, con l'ultimo codice non vengono estratti solo i valori univoci, puoi controllare per favore?
Grazie!
Mea culpa,, mea maxima culpa! Avevo letto male l'ultima domanda!
Sostituisci il codice precedente con la seguente versione:
:
'=========>>
Option Explicit
'--------->>
Public Sub Tester()
Dim WB As Workbook
Dim srcSH As Worksheet, destSH As Worksheet
Dim srcRng As Range, destRng As Range
Dim oDic As Object
Dim arrIn As Variant, arrOut() As Variant
Dim sStr As String
Dim i As Long
Const sFoglioSorgente As String = "Foglio1" '<<=== Modifica
Const sFoglioDestinazione As String = "Foglio4" '<<=== Modifica
Const sIntervalloSorgente As String = "A2:D100" '<<=== Modifica
Const sCellaDestinazione As String = "A1" '<<=== Modifica
Set WB = ThisWorkbook
With WB
Set srcSH = .Sheets(sFoglioSorgente)
Set destSH = .Sheets(sFoglioDestinazione)
End With
Set srcRng = srcSH.Range(sIntervalloSorgente)
Set destRng = destSH.Range(sCellaDestinazione)
arrIn = srcRng.Value
Set oDic = CreateObject("Scripting.Dictionary")
With oDic
For i = LBound(arrIn) To UBound(arrIn)
sStr = arrIn(i, 1)
If Not .exists(sStr) Then
.Add Key:=sStr, Item:=Nothing
End If
Next i
arrOut = .Keys
destRng.Resize(.Count).Value = Application.Transpose(arrOut)
End With
End Sub
'<<=========
Potresti scaricare il mio file di prova Emiliano20180709.xlsm
===
Regards,
Norman