VBA Disattivare/attivare inserimento Macro

Anonimo
2015-07-19T20:30:34+00:00

Ciao a tutti,

Si può con un comando unico disattivare/attivare nella cartella attiva l'inserimento di una macro? Vorrei evitare all'utente di

inserire una sua macro e rendere visibili i fogli protetti con l'istruzione Sheets ("nome foglio").visible=xlSheetveryHidden.

E poi, si può con VBA protetto da password inibire il tasto esegui del menù Macro? 

Grazie per l'attenzione data.

Giuseppe

Microsoft 365 e Office | Excel | Per la casa | Windows

Domanda bloccata. Questa domanda è stata eseguita dalla community del supporto tecnico Microsoft. È possibile votare se è utile, ma non è possibile aggiungere commenti o risposte o seguire la domanda.

0 commenti Nessun commento
Risposta accettata dall'autore della domanda
Anonimo
2015-09-03T08:46:37+00:00

Ciao Giuseppe,

Dopo attenta riflessione ho deciso che Compilerò il mio progetto.

Bene!

Prima però devo realizzare un sistema di controllo degli errori ,sempre possibili, e controlli per prevenire possibili errori dell'utente.

Concordo pienamente: E 'di grande importanza di testare il proprio codice, per quanto possibile e di utilizzare un regime rigoroso di controllo degli errori.

Per il mio codice importante, ho scritto un modulo di classe per gestire con rigore tutti gli errori imprevisti in tale codice.

Questi problemi li ho trascurati un po'.Ora dopo la decisione di rendere disponibile il file, questi due argomenti sono molto importanti. Lo pensi anche tu ?  Attendo tuoi suggerimenti. Grazie ancora per i tuoi consigli. 

Se  la tua intenzione sia di distribuire il codice, credo sia di grande importanza di essere in grado di diagnosticare e correggere i problemi inevitabili a distanza: probabilmente non sar sempre possibile di risolvere tali problemi in persona.

Un suggerimento che vorrei dare è quello di aggiungere numeri di riga al codice finale: in questo modo, Puoi rapidamente e precisamente identificare l'istruzione incriminatoa. Per fare un esempio banale, ho scritto il seguente codice scheletrico e ho intenzionalmente provocato un errore di divisione per zero.

'=========>>

Option Explicit

'--------->>

Public Sub DeleteRange()

    Dim WB As Workbook

    Dim SH As Worksheet

    Dim Rng As Range

    Dim rCell As Range

    Dim delRng As Range

    Dim iLastRow As Long

    Dim CalcMode As Long

10  On Error GoTo ErrHandler

20  Set WB = ThisWorkbook

30  Set SH = WB.Sheets("Foglio1")

40  With SH

50      iLastRow = LastRow(SH, .Columns("A:A"))

60      Set Rng = .Range("A2:A" & iLastRow)

70  End With

80  With Application

90      CalcMode = .Calculation

100     .Calculation = xlCalculationManual

110     .ScreenUpdating = False

120 End With

130 For Each rCell In Rng.Columns(2).Cells

140     With rCell

150         If .Value < Date Then

160             Debug.Print 20 / 0 '<<=== Riga di errore!!

170             If delRng Is Nothing Then

180                 Set delRng = rCell

190             Else

200                 Set delRng = Union(rCell, delRng)

210             End If

220         End If

230     End With

240 Next rCell

250 If Not delRng Is Nothing Then

260     delRng.EntireRow.Delete

270 Else

        'nothing found, do nothing

280 End If

XIT:

290 With Application

300     .Calculation = CalcMode

310     .ScreenUpdating = True

320 End With

330 On Error GoTo 0

340 Exit Sub

ErrHandler:

350 Call MsgBox(Prompt:="Errore " & Err.Number _

                      & vbNewLine _

                      & "(" & Err.Description _

                      & ")" _

                      & vbNewLine & vbNewLine _

                      & "in Riga #: " & Erl _

                      & vbNewLine & _

                        "Nella procedura:  DeleteRange " _

                      & vbNewLine _

                      & "Del Modulo: Module1", _

                Buttons:=vbCritical, _

                Title:="Error Report")

End Sub

'--------->>

Public Function LastRow(SH As Worksheet, _

                        Optional Rng As Range)

360 If Rng Is Nothing Then

370     Set Rng = SH.Cells

380 End If

390 On Error Resume Next

400 LastRow = Rng.Find(What:="*", _

                       after:=Rng.Cells(1), _

                       Lookat:=xlPart, _

                       LookIn:=xlFormulas, _

                       SearchOrder:=xlByRows, _

                       SearchDirection:=xlPrevious, _

                       MatchCase:=False).Row

410 On Error GoTo 0

End Function

'<<=========

Come si pùo vedere dalla seguente immagine

il gestore degli errori segnala il numero di errore, la sua descrizione, il nome della procedura, il nome del modulo e il numero di riga dell'istruzione incriminata. Nella mia esperienza un approccio di questo tipo può risparmiare molto dolore.

Ci sono vari programmi di utilità ampiamente disponibili per aiutarvi a un simile approccio..

Buon lavoro!

===

Regards,

Norman

La risposta è stata utile?

0 commenti Nessun commento

7 risposte aggiuntive

Ordina per: Più utili
  1. Anonimo
    2015-07-20T12:18:46+00:00

    Grazie Norman, è lodevole il tuo impegno rivolto anche ad aprire nuovi orizzonti. Ora ho materiale ha sufficienza da approfondire  e poi prendere una decisione finale.

    Ciao Giuseppe

    La risposta è stata utile?

    0 commenti Nessun commento
  2. Eliminata

    Questa risposta è stata eliminata a causa di una violazione del codice di comportamento. La risposta è stata segnalata manualmente o identificata tramite il rilevamento automatizzato prima dell'esecuzione dell'azione. Per ulteriori informazioni, fai riferimento al codice di comportamento.


    I commenti sono stati disattivati. Ulteriori informazioni

  3. Anonimo
    2015-07-20T07:18:21+00:00

    Grazie Norman, sei stato chiarissimo  e tempestivo nelle risposte.

    Giuseppe.

    La risposta è stata utile?

    0 commenti Nessun commento
  4. Anonimo
    2015-07-19T23:03:16+00:00

    Ciao Giuseppe,

    Si può con un comando unico disattivare/attivare nella cartella attiva l'inserimento di una macro?

    Vorrei evitare all'utente di inserire una sua macro e rendere visibili i fogli protetti con l'istruzione Sheets ("nome foglio").visible=xlSheetveryHidden.

    Se il progetto VBA sia protetto, l'utente non può inserire una macro. Tuttavia, ciò non impedirebbe a un utente di creare una macro in un'altra cartella di lavoro, che potrebbe agire sul file protetto per visualizzare tutti i fogli nascosti.

    E poi, si può con VBA protetto da password inibire il tasto esegui del menù Macro? 

    Per nascondere le macro nel file protetto, potresti inserire la dichiarazione:

           Option Explicit Module 

    alla testa del modulo di codice.

    In alternativa, potresti dichiarare una macro come Private, ad esempio:

    '=========>>

    Private Sub Tester()

    Dim i As Long

        For i = 2 To 4

            ThisWorkbook.Sheets(i).Visible = xlVeryHidden

        Next i

    End Sub

    '<<=========

    Un altro modo sarebbe di dichiarare la macro come una funzione:

    =========>>

    Public Function Tester()

    Dim i As Long

        For i = 2 To 4

            ThisWorkbook.Sheets(i).Visible = xlVeryHidden

        Next i

    End Sub

    '<<=========

    Un'altra possibile soluzione sarebbe di utilizzare alcuni parametri fittizi con la subroutine. Non c'è bisogno di fare nulla con loro all'interno della subroutine stessa, ma includendo loro la procedura non venga elencata nella lista macro. In questo scenario, la macro precedente avrebbe una forma del genere:

    '=========>>

    Public Sub Tester(myDummyParameter As Variant)

    Dim i As Long

        For i = 2 To 4

            ThisWorkbook.Sheets(i).Visible = xlVeryHidden

        Next i

    End Sub

    '<<=========

    Detto questo, si deve essere consapevoli che qualsiasi utente in grado di utilizzare Google potrebbe facilmente superare qualsiasi di queste strategie.

    Una possibile soluzione potrebbe essere quella di creare un addin del tipo COM (CAI) per contenere il codice. Quando si distribuisce un'addin del tipo CAI ad altri utenti, si distribuisce solo il file DLL, non il codice sorgente. Come risultato, il codice sorgente resta assicurato e l'utente non lo vede mai. 

     Per una discussione più dettagliata di questi componenti aggiuntivi, vedi l'articolo Creating A COM Add In  di Chip Pearson a:

         **http://www.cpearson.com/Excel/CreatingCOMAddIn.aspx**

    ===

    Regards,

    Norman

    La risposta è stata utile?

    0 commenti Nessun commento