Creare nuovo file excel estraendo i dati da altri file excel

Ciao Red Mud,

Prova qualcosa del genere:

• Alt-F11 per aprire l'editor di VBA
• Alt-IM per inserire un nuovo modulo di codice
• Nel nuovo modulo vuoto, incolla il seguente codice:

 '=========>>

Option Explicit

'--------->>

Public Sub Tester()

    Dim WB As Workbook

    Dim SH As Worksheet, destSH As Worksheet

    Dim Rng As Range, rCell As Range

    Dim arrExclude As Variant, arrFolders As Variant, arrHeaders As Variant

    Dim iRow As Long

    Dim i As Long, j As Long

    Dim myFile As String

    Dim Res As Variant

    Const sAddress = "F2,K2,C4"

    Const sFolders As String = "**C:\Pippo,C:\Pluto,C:Cat,C:\Dog**"                    '<<=== Modifica

    Const sHeaders As String = "File di Origine,Foglio di Origine,Cliente,Data,Descrizione"

    Set WB = ThisWorkbook

    Set destSH = WB.Sheets(1)

    iRow = 1

    arrExclude = VBA.Array("Calcolo peso", "Forme")

    arrFolders = Split(sFolders, ",")

    arrHeaders = Split(sHeaders, ",")

    destSH.Range("A1:E1").Value = arrHeaders

    On Error GoTo XIT

    Application.ScreenUpdating = False

    For i = LBound(arrFolders) To UBound(arrFolders)

        If Right(arrFolders(i), 1) <> Application.PathSeparator Then

            arrFolders(i) = arrFolders(i) & Application.PathSeparator

        End If

        myFile = Dir(arrFolders(i))

        Do While myFile <> ""

            Set WB = Workbooks.Open(arrFolders(i) & myFile)

            With WB

                For Each SH In WB.Worksheets

                    With SH

                        j = 1

                        Res = Application.Match(.Name, arrExclude, 0)

                        If IsError(Res) Then

                            iRow = iRow + 1

                            With destSH

                                .Cells(iRow, "A").Value = WB.FullName

                                .Cells(iRow, "B").Value = SH.Name

                                Set Rng = SH.Range(sAddress)

                                For Each rCell In Rng.Cells

                                    j = j + 1

                                    .Cells(iRow, j + 1).Value = rCell.Value

                                Next rCell

                            End With

                        End If

                    End With

                Next SH

                .Close savechanges:=False

            End With

            myFile = Dir()

        Loop

    Next i

    destSH.UsedRange.EntireColumn.AutoFit

XIT:

    Application.ScreenUpdating = True

End Sub

'<<=========

• Alt-Q per chiudere l'editor di VBA e tornare a Excel.
• Alt-F8 per aprire  la finestra di gestione delle macro
• Seleziona Tester | Esegui

===

Regards,

Norman

Ciao Norman,

grazie per il tuo interessamento.

1° Il nuovo file deve avere uno solo foglio. Dovrò poi esportare la tabella in Access utilizzare i dati in un   database che dovrò creare.

2° I file da cui prelevare i dati si trovano in diverse directory.

    Ogni directory ha il nome del cliente......in ogni directory sono contenuti i file (articoli specifici di quel cliente) da cui prelevare i dati. Per cui....più clienti...più directory....in ogni directory più file contenenti i dati.

3° SI. In ogni directory del cliente ci sono solo i files relativi agli articoli.

4° I fogli che non sono di interesse si chiamano sempre in modo univoco: "Calcolo peso" e "Forme"

5° Nel nuovo foglio che creeremo vorrei che compaia una riga con il nome del file origine.

6° Si. Gradirei avere una cella indicante nome file sorgente e nome foglio origine.

Non sono pratico del forum...potrei caricare il file di origine così risulterebbe tutto più chiaro.

Grazie.

Ciao

Ciao Norman,

grazie per il tuo interessamento.

1° Il nuovo file deve avere uno solo foglio. Dovrò poi esportare la tabella in Access utilizzare i dati in un   database che dovrò creare.

2° I file da cui prelevare i dati si trovano in diverse directory.

    Ogni directory ha il nome del cliente......in ogni directory sono contenuti i file (articoli specifici di quel cliente) da cui prelevare i dati. Per cui....più clienti...più directory....in ogni directory più file contenenti i dati.

3° SI. In ogni directory del cliente ci sono solo i files relativi agli articoli.

4° I fogli che non sono di interesse si chiamano sempre in modo univoco: "Calcolo peso" e "Forme"

5° Nel nuovo foglio che creeremo vorrei che compaia una riga con il nome del file origine.

6° Si. Gradirei avere una cella indicante nome file sorgente e nome foglio origine.

Non sono pratico del forum...potrei caricare il file di origine così risulterebbe tutto più chiaro.

Grazie.

Ciao

Ciao Red mud,

Almeno per me la spiegazione delle tue esigenze non è sufficiente.

• Non mi è chiaro se il nuovo file deve avere un foglio, tre fogli o 3x fogli, dove x è il numero di file di interesse?
• Sono tutti i file d'interesse in una singola directory?
• Questa directory contiene solo i file di interesse?
• Come possiamo individuare i due fogli che non sono di interesse, ovvero i fogli Pippo e Pluto?
• Si deve mantenere i nomi originali per i nuovi fogli?
• È necessario indicare il nome del file sorgente e fogli di origine?

===

Regards,

Norman