Mulai Cepat: Menyebarkan layanan Pencarian Azure AI menggunakan Terraform

Artikel ini memperlihatkan cara menggunakan Terraform untuk membuat layanan Pencarian Azure AI dengan menggunakan Terraform.

Terraform memungkinkan definisi, pratinjau, dan penyebaran infrastruktur cloud. Dengan menggunakan Terraform, Anda membuat file konfigurasi menggunakan sintaks HCL. Sintaksis HCL memungkinkan Anda menentukan penyedia cloud - seperti Azure - dan elemen yang membentuk infrastruktur cloud Anda. Setelah membuat file konfigurasi, Anda membuat rencana eksekusi yang memungkinkan Anda mempratinjau perubahan infrastruktur sebelum disebarkan. Setelah memverifikasi perubahan, Anda menerapkan rencana eksekusi untuk menyebarkan infrastruktur.

Dalam artikel ini, Anda akan mempelajari cara:

Prasyarat

• Menginstal dan mengonfigurasi Terraform

Menerapkan kode Terraform

1. Buat direktori untuk menguji dan menjalankan sampel kode Terraform. Jadikan sebagai direktori saat ini.

2. Buat file bernama main.tf dan masukkan kode berikut:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = random_pet.rg_name.id
     location = var.resource_group_location
   }
   
   resource "random_string" "azurerm_search_service_name" {
     length  = 25
     upper   = false
     numeric = false
     special = false
   }
   
   resource "azurerm_search_service" "search" {
     name                = random_string.azurerm_search_service_name.result
     resource_group_name = azurerm_resource_group.rg.name
     location            = azurerm_resource_group.rg.location
     sku                 = var.sku
     replica_count       = var.replica_count
     partition_count     = var.partition_count
   }
   

3. Buat file bernama outputs.tf dan masukkan kode berikut:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "azurerm_search_service_name" {
     value = azurerm_search_service.search.name
   }
   

4. Buat file bernama providers.tf dan masukkan kode berikut:

   terraform {
     required_version = ">=1.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   provider "azurerm" {
     features {}
   }
   

5. Buat file bernama variables.tf dan masukkan kode berikut:

   variable "resource_group_location" {
     type        = string
     description = "Location for all resources."
     default     = "eastus"
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
     default     = "rg"
   }
   
   variable "sku" {
     description = "The pricing tier of the search service you want to create (for example, basic or standard)."
     default     = "standard"
     type        = string
     validation {
       condition     = contains(["free", "basic", "standard", "standard2", "standard3", "storage_optimized_l1", "storage_optimized_l2"], var.sku)
       error_message = "The sku must be one of the following values: free, basic, standard, standard2, standard3, storage_optimized_l1, storage_optimized_l2."
     }
   }
   
   variable "replica_count" {
     type        = number
     description = "Replicas distribute search workloads across the service. You need at least two replicas to support high availability of query workloads (not applicable to the free tier)."
     default     = 1
     validation {
       condition     = var.replica_count >= 1 && var.replica_count <= 12
       error_message = "The replica_count must be between 1 and 12."
     }
   }
   
   variable "partition_count" {
     type        = number
     description = "Partitions allow for scaling of document count as well as faster indexing by sharding your index over multiple search units."
     default     = 1
     validation {
       condition     = contains([1, 2, 3, 4, 6, 12], var.partition_count)
       error_message = "The partition_count must be one of the following values: 1, 2, 3, 4, 6, 12."
     }
   }
   

Inisialisasi Terraform

Jalankan terraform init untuk menginisialisasi penyebaran Terraform. Perintah ini mengunduh penyedia Azure yang diperlukan untuk mengelola sumber daya Azure Anda.

terraform init -upgrade

Poin-poin penting:

• Parameter -upgrade meningkatkan plugin penyedia yang diperlukan ke versi terbaru yang sesuai dengan batasan versi konfigurasi.

Buat rencana eksekusi Terraform

Jalankan terraform plan untuk membuat rencana eksekusi.

terraform plan -out main.tfplan

Poin-poin penting:

• Perintah terraform plan membuat rencana eksekusi, tetapi tidak menjalankannya. Perintah ini justru menentukan tindakan yang diperlukan untuk membuat konfigurasi yang ditentukan dalam file konfigurasi Anda. Pola ini memungkinkan Anda memastikan apakah rencana eksekusi telah sesuai dengan ekspektasi Anda sebelum membuat perubahan pada sumber daya aktual.
• Parameter -out opsional memungkinkan Anda menentukan file output untuk rencana. Menggunakan parameter -out memastikan bahwa rencana yang Anda tinjau benar-benar sesuai dengan yang diterapkan.

Terapkan rencana pelaksanaan Terraform

Jalankan terraform apply untuk menerapkan rencana eksekusi ke infrastruktur cloud Anda.

terraform apply main.tfplan

Poin-poin penting:

• Contoh terraform apply perintah mengasumsikan Anda sebelumnya menjalankan terraform plan -out main.tfplan.
• Jika Anda menentukan nama file yang berbeda untuk parameter -out, gunakan nama file yang sama dalam panggilan ke terraform apply.
• Jika Anda tidak menggunakan parameter -out, panggil terraform apply tanpa parameter apa pun.

Memverifikasi hasil

1. Dapatkan nama sumber daya Azure tempat Anda membuat layanan Pencarian Azure AI.

   resource_group_name=$(terraform output -raw resource_group_name)
   

2. Dapatkan nama layanan Pencarian Azure AI.

   azurerm_search_service_name=$(terraform output -raw azurerm_search_service_name)
   

3. Jalankan az search service show untuk menampilkan layanan Pencarian Azure AI yang Anda buat di artikel ini.

   az search service show --name $azurerm_search_service_name \
                          --resource-group $resource_group_name
   

Membersihkan sumber daya

Ketika Anda tidak lagi membutuhkan sumber daya yang dibuat melalui Terraform, lakukan langkah-langkah berikut:

1. Jalankan terraform plan dan tentukan destroy flag.

   terraform plan -destroy -out main.destroy.tfplan
   

   Poin-poin penting:

   • Perintah terraform plan membuat rencana eksekusi, tetapi tidak menjalankannya. Perintah ini justru menentukan tindakan yang diperlukan untuk membuat konfigurasi yang ditentukan dalam file konfigurasi Anda. Pola ini memungkinkan Anda memastikan apakah rencana eksekusi telah sesuai dengan ekspektasi Anda sebelum membuat perubahan pada sumber daya aktual.
   • Parameter -out opsional memungkinkan Anda menentukan file output untuk rencana. Menggunakan parameter -out memastikan bahwa rencana yang Anda tinjau benar-benar sesuai dengan yang diterapkan.

2. Jalankan terraform apply untuk menerapkan rencana eksekusi.

   terraform apply main.destroy.tfplan
   

Memecahkan masalah Terraform pada Azure

Memecahkan masalah umum saat menggunakan Terraform di Azure

Langkah berikutnya