Comparer deux cellules

Ouail BENYAHIA 0 Points de réputation
2026-02-25T14:57:14.3666667+00:00

Bonjour,

Dans le cadre d'un rapprochement entre le chiffre d'affaires du logiciel de gestion commercial de mon client et ma comptabilité j'aimerai mettre en place une formule pour comparer le montant de chaque numéro de commandes.

Par exemple dans la cellule W2, sauriez-vous me dire quelle est la formule à appliquer pour comparer le montant de la cellule K2 à celui de la somme des cellules V2 et V3 svp ?

En gros vérifier que le montant de la commande n°11423 est identique de part et d'autre ? (à gauche c'est le chiffre d'affaires issu du logiciel de gestion commercial et à droite celui de la comptabilité). (et ainsi de suite pour chaque commandes).

Merci !

Microsoft 365 et Office | Excel | Pour les entreprises | Windows
0 commentaires Aucun commentaire

Réponse recommandée par le modérateur
Hecatonchire 54,030 Points de réputation Modérateur bénévole
2026-03-02T13:36:03.0233333+00:00

Je te propose pour W2

=LET(s_v;SOMME.SI.ENS($V$2:$V$259;$T$2:$T$259;T2);s_k;SOMME.SI.ENS($K$2:$K$143;$B$2:$B$143;T2);e;s_v-s_k;SI(ABS(e)<0,1;0;"Écart de " & e))

=> générant par exemple en cas d'écart : "Écart de 10"

ou

=LET(s_v;SOMME.SI.ENS($V$2:$V$259;$T$2:$T$259;T2);s_k;SOMME.SI.ENS($K$2:$K$143;$B$2:$B$143;T2);e;s_v-s_k;SI(ABS(e)<0,1;0;e))

=> générant par exemple en cas d'écart : 10

Cette réponse a-t-elle été utile ?

1 personne a trouvé cette réponse utile.

12 réponses supplémentaires

  1. IlirU 2,651 Points de réputation Modérateur bénévole
    2026-03-01T10:50:27.7133333+00:00

    Bonjour,

    Je ne parle pas français, donc les informations ci‑dessous sont traduites par une IA. La formule que j’ai créée pour votre cas est en Excel anglais, et sa conversion en français a également été faite via l’IA. J’espère que la formule a été fournie correctement.

    =LET(

    N°Comm; B2:B143;

    N°CDE; T2:T259;

    uB; UNIQUE(N°Comm);

    uT; UNIQUE(N°CDE);

    seqB; SEQUENCE(; NB(uB); MIN(uB));

    seqT; SEQUENCE(; NB(uT); MIN(uT));

    missB; TRANSPOSE(FILTRE(seqB; NON(BYCOL(uB = seqB; OU))));

    missT; TRANSPOSE(FILTRE(seqT; NON(BYCOL(uT = seqT; OU))));

    tc; TOCOL(missT / NON(missT = TRANSPOSE(missB)); 3);

    rep; REPT(tc & ",0,"; NB(tc));

    parsed; --FRACTIONNER.TEXTE(JOINDRE.TEXTE(";";; rep); ","; ";"; VRAI);

    flat; TOCOL(parsed; 3);

    wr; WRAPROWS(flat; 2);

    d; TRIER(VSTACK(wr; HSTACK(N°CDE; V2:V259)));

    ARRONDI(K2:K143 - BYROW(N°Comm; LAMBDA(a; SOMME(TOCOL(DROP(d;; 1) / (a = TAKE(d;; 1)); 3)))); 2)

    )

    Étant donné que, d’après mes expériences précédentes, la traduction des formules utilisant les nouvelles fonctions d’Excel en français n’a pas toujours été entièrement exacte, vous pouvez télécharger mon fichier via le lien ci‑dessous.

    https://1drv.ms/x/c/511e91319deee91f/IQC2H9_OO07-RaSI1rzVNyafAbbXT7Mllr3KLvDBEe04jSQ?e=FHecld

    La formule est dynamique et elle est appliquée dans la cellule W2. Elle fonctionne sous Excel 365.

    Merci de m’informer si la formule a fonctionné pour vous ou non. Si elle fonctionne, je vous serais reconnaissant(e) de marquer ma réponse comme Réponse valide et, si possible, de laisser un vote positif, car cela permettra d’aider d’autres utilisateurs du forum.

    IlirU

    Cette réponse a-t-elle été utile ?


  2. Hecatonchire 54,030 Points de réputation Modérateur bénévole
    2026-02-27T16:47:38.2633333+00:00

    Bonjour

    "ça me met Ecart sur toutes les cellules de la colonne W" => La formule que je t'ai fournis me semble fonctionner. Elle indique si la commande en colonne B présente des écarts.

    EXCEL_Bh5TEydT3X

    Voici une formule indiquant si la commande en colonne T présente des écarts

    =SI(SOMME.SI.ENS($V$2:$V$259;$T$2:$T$259;T2)=SOMME.SI.ENS($K$2:$K$143;$B$2:$B$143;T2);0;"Ecart")

    EXCEL_MXacCeB5d8

    Je n'ai pas respecté "La cellule W3 devant donc être vide" car cette contrainte risque ne complexifier fortement la formule. Si c'est vraiment important je pourrais tenter de te fournir une formule.

    Cette réponse a-t-elle été utile ?


  3. Ouail BENYAHIA 0 Points de réputation
    2026-02-27T07:39:20.8+00:00

    Alors ça se rapproche mais ce n'est pas tout à fait ça.

    Autrement dit : sur le commande n°11423 on voit que V2+V3-K2=0 donc il faudrait que ce soit affiché 0 dans W2.

    La cellule W3 devant donc être vide.

    Exemple suivant : commande 11424 : V4+V5-K3=0 et ainsi de suite pour chaque commandes.

    Le tableau est le même que celui transmis.

    J'ai appliqué la formule que vous m'avez indiqué mais en la recopiant vers le bas ça me met Ecart sur toutes les cellules de la colonne W ce n'est donc pas tout à fait ça.

    Merci !

    Cette réponse a-t-elle été utile ?

    0 commentaires Aucun commentaire

  4. Hecatonchire 54,030 Points de réputation Modérateur bénévole
    2026-02-26T17:13:39.0333333+00:00

    J'ai répondu de manière un peu trop "terre à terre". La formule proposée fonctionne (même en recopie) mais à condition que l'ordre des lignes corresponde et se limite à 2 valeurs en colonne V.

    Un version se basant sur le numéros de cde (ordre des lignes et nombre de valeurs en colonne v libre)

    =SI(SOMME.SI.ENS($V$2:$V$259;$T$2:$T$259;B2)=K2;"";"Ecart")

    Si pas d'écart la cellule est vide sinon elle écrit "Ecart"

    Si tu veux la somme ou l'écart dis le moi (donne alors ta version d'Excel)

    Cette réponse a-t-elle été utile ?

    0 commentaires Aucun commentaire

Votre réponse

Les réponses peuvent être marquées comme « Acceptées » par l’auteur de la question et « Recommandées » par les modérateurs, ce qui aide les utilisateurs à savoir que la réponse a résolu le problème de l’auteur.