Rychlý průvodce: Nasazení služby Azure AI Vyhledávač pomocí Terraformu

Tento článek ukazuje, jak pomocí Terraformu vytvořit službu Azure AI Vyhledávač pomocí Terraformu.

Terraform umožňuje definici, náhled a nasazení cloudové infrastruktury. Pomocí Terraformu vytvoříte konfigurační soubory pomocí syntaxe HCL. Syntaxe seznamu HCL umožňuje zadat poskytovatele cloudu , například Azure, a prvky, které tvoří vaši cloudovou infrastrukturu. Po vytvoření konfiguračních souborů vytvoříte plán provádění, který vám umožní zobrazit náhled změn infrastruktury před jejich nasazením. Jakmile ověříte změny, použijete plán provádění k nasazení infrastruktury.

V tomto článku získáte informace o těchto tématech:

Požadavky

• Nainstalujte a nakonfigurujte Terraform

Implementace kódu Terraformu

1. Vytvořte adresář pro testování a spuštění ukázkového kódu Terraformu. Nastavte ho jako aktuální adresář.

2. Vytvořte soubor s názvem main.tf a vložte následující kód:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = random_pet.rg_name.id
     location = var.resource_group_location
   }
   
   resource "random_string" "azurerm_search_service_name" {
     length  = 25
     upper   = false
     numeric = false
     special = false
   }
   
   resource "azurerm_search_service" "search" {
     name                = random_string.azurerm_search_service_name.result
     resource_group_name = azurerm_resource_group.rg.name
     location            = azurerm_resource_group.rg.location
     sku                 = var.sku
     replica_count       = var.replica_count
     partition_count     = var.partition_count
   }
   

3. Vytvořte soubor s názvem outputs.tf a vložte následující kód:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "azurerm_search_service_name" {
     value = azurerm_search_service.search.name
   }
   

4. Vytvořte soubor s názvem providers.tf a vložte následující kód:

   terraform {
     required_version = ">=1.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   provider "azurerm" {
     features {}
   }
   

5. Vytvořte soubor s názvem variables.tf a vložte následující kód:

   variable "resource_group_location" {
     type        = string
     description = "Location for all resources."
     default     = "eastus"
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
     default     = "rg"
   }
   
   variable "sku" {
     description = "The pricing tier of the search service you want to create (for example, basic or standard)."
     default     = "standard"
     type        = string
     validation {
       condition     = contains(["free", "basic", "standard", "standard2", "standard3", "storage_optimized_l1", "storage_optimized_l2"], var.sku)
       error_message = "The sku must be one of the following values: free, basic, standard, standard2, standard3, storage_optimized_l1, storage_optimized_l2."
     }
   }
   
   variable "replica_count" {
     type        = number
     description = "Replicas distribute search workloads across the service. You need at least two replicas to support high availability of query workloads (not applicable to the free tier)."
     default     = 1
     validation {
       condition     = var.replica_count >= 1 && var.replica_count <= 12
       error_message = "The replica_count must be between 1 and 12."
     }
   }
   
   variable "partition_count" {
     type        = number
     description = "Partitions allow for scaling of document count as well as faster indexing by sharding your index over multiple search units."
     default     = 1
     validation {
       condition     = contains([1, 2, 3, 4, 6, 12], var.partition_count)
       error_message = "The partition_count must be one of the following values: 1, 2, 3, 4, 6, 12."
     }
   }
   

Inicializovat Terraform

Spusťte terraform init pro inicializaci nasazení Terraformu. Tento příkaz stáhne poskytovatele Azure potřebného ke správě prostředků Azure.

terraform init -upgrade

Klíčové body:

• Parametr -upgrade aktualizuje potřebné plug-iny poskytovatele na nejnovější verzi, která splňuje verzní omezení konfigurace.

Vytvoření plánu provádění Terraformu

Spusťte terraform plan pro vytvoření plánu provádění.

terraform plan -out main.tfplan

Klíčové body:

• Příkaz terraform plan vytvoří plán provádění, ale nespustí ho. Místo toho určuje, jaké akce jsou nezbytné k vytvoření konfigurace zadané v konfiguračních souborech. Tento model umožňuje ověřit, jestli plán provádění odpovídá vašim očekáváním, než provede jakékoli změny skutečných prostředků.
• Volitelný -out parametr umožňuje zadat výstupní soubor pro plán. Použití parametru -out zajišťuje, že plán, který jste zkontrolovali, je přesně ten, který se uplatní.

Použijte prováděcí plán Terraformu

Spusťte terraform apply a aplikujte plán provedení do vaší cloudové infrastruktury.

terraform apply main.tfplan

Klíčové body:

• terraform apply Ukázkový příkaz předpokládá, že jste dříve spustili terraform plan -out main.tfplan.
• Pokud jste pro -out parametr zadali jiný název souboru, použijte stejný název souboru při volání terraform apply.
• Pokud jste parametr nepoužíli -out , zavolejte terraform apply bez parametrů.

Ověření výsledků

1. Získejte název Azure prostředku, ve kterém jste vytvořili službu Azure AI Vyhledávač.

   resource_group_name=$(terraform output -raw resource_group_name)
   

2. Získejte název služby Azure AI Vyhledávač.

   azurerm_search_service_name=$(terraform output -raw azurerm_search_service_name)
   

3. Proveďte příkaz az search service show pro zobrazení služby Azure AI Vyhledávač, kterou jste vytvořili v tomto článku.

   az search service show --name $azurerm_search_service_name \
                          --resource-group $resource_group_name
   

Uvolnění prostředků

Pokud už prostředky vytvořené přes Terraform nepotřebujete, proveďte následující kroky:

1. Spusťte terraform plan a zadejte příznak destroy.

   terraform plan -destroy -out main.destroy.tfplan
   

   Klíčové body:

   • Příkaz terraform plan vytvoří plán provádění, ale nespustí ho. Místo toho určuje, jaké akce jsou nezbytné k vytvoření konfigurace zadané v konfiguračních souborech. Tento model umožňuje ověřit, jestli plán provádění odpovídá vašim očekáváním, než provede jakékoli změny skutečných prostředků.
   • Volitelný -out parametr umožňuje zadat výstupní soubor pro plán. Použití parametru -out zajišťuje, že plán, který jste zkontrolovali, je přesně ten, který se uplatní.

2. Spusťte terraform apply pro použití plánu provádění.

   terraform apply main.destroy.tfplan
   

Řešení potíží s Terraformem v Azure

Řešení běžných problémů při používání Terraformu v Azure

Další kroky