Excel raadsel

Hey Bocculus,

Ik ben er nog steeds niet uit. Ik ga het deze namiddag nog een keertje proberen :)

Groeten,

Kenny

Hey Bocculus,

Bedankt voor je antwoord!

Ik ben nog even dagen van huis, maar ik ga je antwoord dit weekend eens goed bekijken!

IK heb het gevoel dat we er bijna zijn :D

Ik hou je op de hoogte.

Groeten,

Kenny

Beste Kenny,

In jouw antwoord van 25 november 21:49 laat je een paar bankafschriften zien, zoals je ze van de bank krijgt. In het meegestuurde bestand zien ze er iets anders uit. Ook is de datum hier in de omschrijving soms anders dan in de datumkolom. Het lijkt er dus op, dat je (soms) handmatig delen (datum, bedrag) uit de omschrijving haalt. Wel zegt je, dat het bedrag de datum in een aparte kolom wordt meegegeven.

Ik ben uitgegaan van het door jou meegeleverde bestand en heb daarvoor een paar suggesties. Neem ervan wat je kunt gebruiken, aanpassingen zijn mogelijk.

Het gaat om 600 boekingen per jaar, zeg je. Dus de moeite waard.

Maak een paar benoemde bereiken aan (Formules, Namen):

Datum:  =VERSCHUIVING(Januari!$B$3;0;0;AANTAL(Januari!$B$3:$B$10000))

Fout: =VERSCHUIVING(Datum;0;7)

Bereik tot en met 10000, omdat je meerdere jaren in dit bestand kunt verwerken. 10000/600  is meer dan 16 jaar.

Haal de datum uit kolom Details:

B3:   =DATUM("2018";DEEL(D3;1+VIND.SPEC("-";D3);2);DEEL(D3;-2+VIND.SPEC("-";D3);2))

B17 heeft een datum uit 2017. De formule kan ieder jaar worden aangepast voor het jaar, eventueel in B1 het jaartal (2018). Het vorige jaar moet dan worden vastgezet via kopiëren speciaal, waarden.

Haal het bedrag uit Details:

C3: =--DEEL(D3;-9+MIN(ALS.FOUT(VIND.SPEC({"-";"+"};D3;VIND.SPEC("-";D3)+1);""));9)

Invoeren als matrixformule (ctrl shift enter), controleer of de accolades worden geplaatst.

Dan stel ik voor, voor de overzichtelijkheid, om twee kolommen in te voegen na de omschrijving (details).

E2: Bij, F2: Af.

E3:   =ALS(ISGETAL(VIND.SPEC("+";$D3));$C3;0)

F3:  =ALS(ISGETAL(VIND.SPEC("+";$D3));0;$C3)

Maak de bedragen (B, E en F) op als bijv. :   _ € * #.##0,00_ ;_ € * -#.##0,00_ ;;

Hiermee verdwijnt de nul ook uit de cel.

Kolom G en H dus resp. Trefwoorden en Groepen.

Om het indexeren te vereenvoudigen, kun je het volgende doen.

In I2: Fout, J2: Rijnummer.

I3: =ALS(ISFOUT(G3);RIJ();"")

J3: =ALS.FOUT(KLEINSTE($I$3:$I$10000;RIJ($A1));"")

Dit geeft in kolom I het rijnummer van een niet-geïndexeerde cel, In kolom J komen de niet geïndexeerde rijen bovenaan. Je kunt nu naar beneden scrollen om naar de betreffende rijen te gaan. Als je bijvoorbeeld de eerste tien rijen vastzet (Beeld, deelvensters blokkeren), dan blijven de laagste rijnummers steeds in het zicht.

L3:  =AANTAL(Datum) ,  M3: Afschriften (het aantal boekingen).

L4:  =AANTAL(Fout) ,      M4: Niet benoemd

Formules uiteraard doorvoeren naar beneden via een dubbelklik op de vulgreep.

Groet,

Bocculus

Hey Bocculus,

Gelukt!! Hartelijk bedankt!

Het gaat om alle maandelijkse financiële verrichtingen binnen een huishouden. Maw rond de 50 verrichtingen per maand. Extra hulpmiddelen zijn zéker interessant!

Hieronder het documentje :)

Groeten,

Kenny