Copiare un foglio Excel in più file Excel

Difficile trovare qualcosa di preconfezionato che possa soddisfare le svariate esigenze.

Qui un esempio di quello che si potrebbe fare (mutuando parte del codice proposto da Eleuterio con qualche aggiustamento):

Sub CopiareUnFoglioInPiuFile()

Dim sFileOrigineFullName As String

Dim sPercorsoFileDestinazione As String

Dim strFileDest As String

Dim WkbOrig As Workbook, WkbDest As Workbook

With Application.FileDialog(msoFileDialogFilePicker)

  .Title = "Seleziona File Origine Dati" 

  .AllowMultiSelect = False 

  With .Filters 

     .Clear 

     .Add "xlsx", "\*.xlsx" 

  End With 

  If .Show Then 

     sFileOrigineFullName = .SelectedItems(1) 

  End If 

End With

If sFileOrigineFullName <> vbNullString Then

  With Application.FileDialog(msoFileDialogFolderPicker) 

     .Title = "Seleziona Percorso File Destinazione" 

     If .Show Then 

        sPercorsoFileDestinazione = .SelectedItems(1) 

     End If 

  End With 

End If

If sPercorsoFileDestinazione <> vbNullString Then

  Application.ScreenUpdating = False 

  Set WkbOrig = Workbooks.Open(sFileOrigineFullName) 

  strFileDest = Dir(sPercorsoFileDestinazione & "\\*.xlsx") 

  Do Until strFileDest = "" 

     If sFileOrigineFullName <> sPercorsoFileDestinazione & "\" & strFileDest Then 

        Set WkbDest = Workbooks.Open(sPercorsoFileDestinazione & "\" & strFileDest) 

        WkbOrig.Worksheets("Foglio1").Copy WkbDest.Sheets(1) 

        WkbDest.Close True 

     End If 

     strFileDest = Dir 

  Loop 

  WkbOrig.Close False 

  Application.ScreenUpdating = True 

  MsgBox "Copia terminata!", vbInformation, "CopiareUnFoglioInPiuFile" 

End If

End Sub

Qui un file dove nel modul1 è presente il codice da copiare (se il copia/incolla dal sito dovesse dare problemi):

File Esempio

Prova a vedere se riesci ad ottenere quello che desideri

Buongiorno,

grazie per la gentile risposta !

Data l'inesperienza pensavo che vi fosse già un'applicazione sviluppata da qualcuno.

Qualcosa di preconfezionato da sfruttare oppure semplice aggiustamenti partendo dal registratore.

Se non c'è ... peccato !