Excel con elenchi a discesa condizionati

Anonimo
2018-07-19T11:16:02+00:00

Buongiorno a tutti,

ho cercato varie soluzioni con funzioni tipo Indiretto, CercaVert, etc, ma non riesco a venirne a capo. 

Chiedo gentilmente un aiuto.

Ho un foglio Excel con queste 3 colonne:

A       B        C

Q1 1/4/18 Rossi   

Q1 2/4/18 Bianchi

Q2 1/4/18 Verdi

Q3 2/4/18 Gialli

Q4 1/4/18 Blu

Q4 2/4/18 Blu

In un secondo foglio avrei bisogno di un elenco a discesa in una colonna, supponiamo la A, che mi elenchi univocamente gli elementi della prima colonna suddetta, cioè Q1,Q2,Q3,Q4. Sulla base di questa selezione la colonna B sempre di questo secondo foglio dovrebbe contenere in un elenco a discesa solo le date corrispondenti , cioè 1/4/18 e 2/4/18 se avessi scelto Q1 nella colonna A, oppure solo 2/4/18 se avessi scelto Q3. Quindi una terza colonna, C, con un elenco a discesa in base alle prime due selezioni, cioè elenchi solo Bianchi se nella colonna B avessi selezionato come data 2/4/18 e Q1 nella A.

Spero sia tutto chiaro.

Grazie a tutti, Max.

Microsoft 365 e Office | Excel | Per la casa | Windows

Domanda bloccata. Questa domanda è stata eseguita dalla community del supporto tecnico Microsoft. È possibile votare se è utile, ma non è possibile aggiungere commenti o risposte o seguire la domanda.

0 commenti Nessun commento
Risposta accettata dall'autore della domanda
Anonimo
2018-07-25T19:59:45+00:00

Buonasera a tutti possibile soluzione solo con formule

In foglio1 ho ricostruito la tabella esempio da A2 a C7

In foglio2 da A2 a C2 le celle da usare per le convalide uso tre colonne di sevizio la H la I e la J (eventualmente da nascondere)

in H2 da trascinare in basso

=SE.ERRORE(INDICE(Foglio1!$A$2:$A$100;CONFRONTA(0;INDICE(CONTA.SE($H$1:H1;Foglio1!$A$2:$A$100&""););0));"")

in I2 da trascinare in basso

=SE.ERRORE(INDICE(Foglio1!B$2:B$100;AGGREGA(15;6;RIF.RIGA($A$2:$A$100)/(Foglio1!$A$2:$A$100=$A$2)-1;RIF.RIGA($A1)));"")

in J2 da trascinare in basso

=SE.ERRORE(INDICE(Foglio1!C$2:C$100;AGGREGA(15;6;RIF.RIGA($A$2:$A$100)/(Foglio1!$A$2:$A$100&Foglio1!$B$2:$B$100=$A$2&$B$2)-1;RIF.RIGA($A1)));"")

seleziona la cella A2 del foglio2 DATI->CONVALIDA DATI->ELENCO

nella barra della formula incolla

=SCARTO($H$2;;;MATR.SOMMA.PRODOTTO(--($H$2:$H$100<>"")))

ripeti la procedura per le celle B2 e C2 incollando per B2

=SCARTO($I$2;;;MATR.SOMMA.PRODOTTO(--($I$2:$I$100<>"")))

per C2

=SCARTO($J$2;;;MATR.SOMMA.PRODOTTO(--($J$2:$J$100<>"")))

allego link per scaricare file di lavoro

https://www.dropbox.com/s/9mj9bymrr1tagh6/convalida.xlsx?dl=0

La risposta è stata utile?

0 commenti Nessun commento

6 risposte aggiuntive

Ordina per: Più recente
  1. Anonimo
    2018-07-25T08:35:03+00:00

    Ciao Andrea, grazie, nel frattempo sto provando con Microsoft Query.

    La risposta è stata utile?

    0 commenti Nessun commento
  2. Anonimo
    2018-07-25T08:14:10+00:00

    Ciao Max

    mentre attendi che uno dei nostri moderatori ti risponda, potresti dare un'occhiata anche al nostro forum specializzato sulla macro di Excel MSDN. Ovviamente, se dovessi aver bisogno di ulteriore supporto, sono a tua disposizione

    Buona gionata

    Andrea

    La risposta è stata utile?

    0 commenti Nessun commento