creare un foglio "master" o riepilogo" in automatico

ciao Norman

...il collegamento ipertestuale, invece, forse è meglio continuare a lasciarlo "a mano", vero? non è remota la possibilità che i fogli cambino nome. In tal caso, adesso, correggo manualmente il collegamento ipertestuale. Se lo facciamo in VBA, bisognerebbe cambiare la programmazione, vero?

a presto

Ciao, Normann

non sono riuscito a scaricare il file, ma ho copiato l'intero procedimento, seguendo le Tue disposizioni. funziona!!

quando inserisco un nuovo rigo, mi compare una prima finestra di errore: "La cella A... non contiene un comando valido. vuoi continuare?" rispondo di "si"; ne compare un'altra: "vuoi cancellare le celle? B...:K..."; rispondo di "no"; creo un collegamento valido in A, ed il gioco è fatto!!

mi resta da trascinare "a mano" le formule in M e in N. se è possibile inserire nel procedimento anche questo passaggio, bene. Altrimenti, va bene lo stesso.

a presto

Grazie mille

:-)

Ciao Norman, grazie per l'attenzione.

Ciao vitaliano,

Nel file Master, 

• Fai clic dx sulla linguetta del foglio Riepilogo
• Seleziona l'opzione Visualizza Codice
• Incolla il seguente codice:

'=========>>

Option Explicit

'--------->>

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim Rng As Range, Rng2 As Range, rCell As Range

    Dim sStr As String

    Dim i As Long

    Dim Res As VbMsgBoxResult

    Dim CalcMode As Long

    If Target.Row = 1 Then

        Exit Sub

    End If

    Set Rng = Intersect(Me.Range("A:A"), Target)

    If Not Rng Is Nothing Then

        On Error GoTo XIT

        With Application

            CalcMode = .Calculation

            .Calculation = xlCalculationManual

            .EnableEvents = False

            .ScreenUpdating = False

        End With

        For Each rCell In Rng.Cells

            With rCell

                On Error Resume Next

                sStr = Split(.Formula, "!")(0)

                If Err.Number = 0 Then

                    rCell.Offset(0, 1).Formula = sStr & "!" & "H10"

                    For i = 2 To 11

                        rCell.Offset(0, i).Formula = sStr & "!" & "I" & i - 1

                    Next i

                Else

                    Err.Clear

                    Select Case MsgBox("La cella " _

                                     & rCell.Address(0, 0) _

                                     & " non comprende un collegmento valido!" _

                                     & vbNewLine & vbNewLine _

                                     & "Vuoi continuare?", _

                                       Buttons:=vbYesNo Or vbExclamation Or vbDefaultButton1, _

                                       Title:="CONTROLLA COLLEGAMENTO")

                    Case vbNo

                        Application.Undo

                        GoTo XIT

                    Case vbYes

                        Set Rng2 = rCell.Offset(0, 1).Resize(1, 10)

                        Res = MsgBox(Prompt:="Vuoi cancellare le celle? " _

                                           & Rng2.Address(0, 0), _

                                     Buttons:=vbYesNo, _

                                     Title:="CANCELLARE FORMULE?")

                        If Res = vbYes Then

                            Rng2.ClearContents

                        End If

                    End Select

                End If

            End With

        Next rCell

    End If

XIT:

    With Application

        .Calculation = CalcMode

        .EnableEvents = True

        .ScreenUpdating = True

    End With

End Sub

'<<=========

• Alt-Q per chiudere l'editor di VBA e tornare a Excel.

D'ora in poi, l'immissione di un collegamento valido nella colonna A inserirà automaticamente i collegamenti necessari nelle colonne B: L

Potresti scaricare il mio file di prova Vitaliano20150521.xlsm a: http://1drv.ms/1BdXtCG

===

Regards,

Norman