esportare tabelle da access in excel

Anonimo
2015-03-18T12:08:29+00:00

Ho una serie di tabelle in access e vorrei esportarle tutte in un unico file Excel (cartella Excel con all'interno i vari fogli che corrisponderanno alle tabelle di cui sopra)... l'unica cosa che riesco ad ottenere è che viene trasferita sempre e solo il primo foglio della mia cartella di lavoro...

di seguito il codice che utilizzo:

Function Esporto() DoCmd.TransferSpreadsheet acExport, 8, "Lun", "C:\Documents and Settings\All Users\Desktop\Validazione\validazione.xls", False, "B1:o12000" False, "B1:o12000"Set xl = CreateObject("Excel.Application") ' dove sSource = path completo del tuo file .xls sSource = "C:\Documents and Settings\All Users\Desktop\Validazione\validazione.xls"With xl ' .Workbooks.Add .Workbooks.Open sSource ' .Sheets(sSheet).Activate .Visible = True End With End Function  

nel mio caso la cartella è "validazione.xls"  ed i fogli di lavoro sono divisi per giorni della settimana (lun, mar, ecc

Microsoft 365 e Office | Access | Per la casa | Windows

Domanda bloccata. Questa domanda è stata eseguita dalla community del supporto tecnico Microsoft. È possibile votare se è utile, ma non è possibile aggiungere commenti o risposte o seguire la domanda.

0 commenti
Risposta accettata dall'autore della domanda
Anonimo
2015-03-24T17:11:44+00:00

Ciao Sandro!

Posto di nuovo il codice perché ho l'impressione che non ci siamo capiti riguardo la posizione dei due ScreenUpdating. Se sbaglio, scusami.

Option Compare Database

Option Explicit

#Const DevMode = 0

Public Sub Test4()

Const cstrProc = "Test4"

On Error GoTo ErrH

Dim e As Long

' --- Personalizzare -------------------- >

'

Const cstrXlsFullPath = "D:\Percorso\Test1"

Const cblnShow = False

' --------------------------------------- <

Const cstrXlClass = "Excel.Application"

Const cstrFullName = "<FullName>"

Const cstrCnn = "OLEDB;Provider=Microsoft.ACE.OLEDB.12.0" _

             & ";Data Source=" & cstrFullName _

             & ";Mode=Read;"

Dim dbp As Access.CurrentProject

Dim dbs As DAO.Database

Dim tdf As DAO.TableDef

#If DevMode Then

  Dim xlApp   As Excel.Application

  Dim xlWbk   As Excel.Workbook

  Dim xlWsh   As Excel.Worksheet

  Dim xlQry   As Excel.QueryTable

#Else

  Const xlCmdTable = 3

  Dim xlApp As Object

  Dim xlWbk As Object

  Dim xlWsh As Object

  Dim xlQry As Object

#End If

Dim blnNotRunning As Boolean

Dim strCnn    As String

Dim strTable  As String

Dim lngTable  As Long

    With Application

      Set dbp = .CurrentProject

      Set dbs = .CurrentDb

    End With

    strCnn = Replace(cstrCnn, cstrFullName, dbp.FullName)

    Debug.Print strCnn

    On Error Resume Next

    Set xlApp = GetObject(Class:=cstrXlClass)

    e = Err.Number

    On Error GoTo ErrH

    If e Then

      blnNotRunning = True

      Set xlApp = CreateObject(Class:=cstrXlClass)

    End If

    With xlApp

      If blnNotRunning And cblnShow Then .Visible = True

      .ScreenUpdating = False

      Set xlWbk = .Workbooks.Add

    End With

    With xlWbk.Worksheets

      .Add Count:=GetTableDefsCount(dbs) - .Count

    End With

    For Each tdf In dbs.TableDefs

      If (tdf.Attributes And dbSystemObject) = False Then

        lngTable = lngTable + 1

        strTable = tdf.Name

        Set xlWsh = xlWbk.Worksheets.Item(lngTable)

        With xlWsh

          .Name = strTable

          Set xlQry = .QueryTables.Add(Connection:=strCnn _

                                     , Destination:=.Range("A1"))

        End With

        With xlQry

          .CommandType = xlCmdTable

          .CommandText = strTable

          .AdjustColumnWidth = True

          .FieldNames = True

          .Refresh

          .Delete

        End With

        Set xlQry = Nothing

      End If

    Next

    MsgBox "Fatto!"

ExtP:

    On Error Resume Next

    Set tdf = Nothing

    Set dbs = Nothing

    Set dbp = Nothing

    With xlApp

      .ScreenUpdating = True

      .DisplayAlerts = False

    End With

    xlWbk.Close SaveChanges:=True _

              , FileName:=cstrXlsFullPath

    If cblnShow Then

      xlApp.Visible = True

    Else

      If blnNotRunning Then xlApp.Quit

    End If

    Set xlQry = Nothing

    Set xlWsh = Nothing

    Set xlWbk = Nothing

    Set xlApp = Nothing

    Exit Sub

ErrH:

    With Err

      MsgBox "ERR#" & CStr(.Number) _

           & vbNewLine & .Description _

           , vbOKOnly Or vbCritical, cstrProc

    End With

    Resume ExtP

End Sub

La risposta è stata utile?

1 persona ha trovato utile questa risposta.
0 commenti

42 risposte aggiuntive

Ordina per: Più recente
Più utili Più recente Meno recente
  1. Anonimo
    2015-03-19T20:58:04+00:00

    ciao  Maurizio,

    molto intelligente il tuo modo di contare i files.

    nella query41 seleziono i nomi delle tabella, con classico statement :

    SELECT MSysObjects.Id, MSysObjects.Lv, MSysObjects.LvExtra, MSysObjects.LvModule, MSysObjects.LvProp, MSysObjects.Name, MSysObjects.Type

    FROM MSysObjects

    WHERE (((MSysObjects.Type)=1) AND ((Left([Name],4))<>"Msys"));

    ci sono limiti che potrebbero essere gestiti con gli errori, tipo lo sforamento del numero massimo di righe 1.048.576 e ho notato che le tabelle collegate non si possono esportare....

    questa la routine completa mi sembra tutto sommato, buona che dici?

    Grazie e buona serata,

    Ciao, Sandro.

    Sub tabelleToXls2()

    Dim tbf As DAO.TableDef

     Dim newWorkBook As Object, newWorkSheet As Object, newExcelIstance As Object, rRange As Object

     Dim rst As DAO.Recordset

     Dim strSql As String

     Dim i As Integer, j As Integer

     Set newExcelIstance = CreateObject("Excel.application")

     Set newWorkBook = newExcelIstance.Workbooks.add

     newWorkBook.Worksheets.add Count:=DCount("name", "Query41") - newWorkBook.Worksheets.Count - 1

     j = 1

    For Each tbf In CurrentDb.TableDefs

          If (tbf.Attributes And dbSystemObject) Then

              Else

                  For i = 0 To tbf.Fields.Count - 1

                      If i = 0 Then

                        Set newWorkSheet = newWorkBook.Worksheets.Item(j)

                        newWorkSheet.Name = tbf.Name

                      End If

                      newWorkSheet.cells(1, i + 1) = tbf.Fields(i).Name

                      strSql = "select [" & tbf.Fields(i).Name & "] from [" & tbf.Name & "]"

                      Set rRange = newWorkSheet.Range(newWorkSheet.cells(2, i + 1), newWorkSheet.cells(tbf.RecordCount + 1, i + 1))

                      Select Case FieldTypeName(tbf.Fields(i))

                             Case "Date/Time"

                                 rRange.NumberFormat = "mm/dd/yyyy"

                             Case "Currency"

                                 rRange.NumberFormat = "$ #,##0.00"

                             Case "Single", "Double"

                                  rRange.NumberFormat = "#,##0.00"

                     End Select

                      rRange.CopyFromRecordset DBEngine(0)(0).OpenRecordset(strSql, dbOpenDynaset)

                 Next

                  newWorkSheet.cells.EntireColumn.AutoFit

                  j = j + 1

          End If

      Next

      newWorkBook.Close SaveChanges:=True, fileName:=strPath

      MsgBox "file xls con tutte le tabelle in " & strPath, vbInformation, "Informazione"

     Set tbf = Nothing

      Set newExcelIstance = Nothing

      Set newWorkBook = Nothing

      Set newWorkSheet = Nothing

    La risposta è stata utile?

    0 commenti
  2. Anonimo
    2015-03-19T19:07:02+00:00

    ciao Maurizio,

    ....mi correggo...la tua routine esporta...! ;-))) era il mio pc che non mi consentiva di salvare i C:....

    a dopo, Sandro.

    La risposta è stata utile?

    0 commenti
  3. Anonimo
    2015-03-19T19:03:12+00:00

    ciao Maurizio,

    errore pacchiano sull'assegnazione del range su cui applicare il formato.....

    questo per intenderci :

    Set rRange = newWorkSheet.Range(newWorkSheet.cells(3, i + 1), newWorkSheet.cells(3, tbf.RecordCount + 2))

    questa l'istruzione corretta:

    Set rRange = newWorkSheet.Range(newWorkSheet.cells(2, i + 1), newWorkSheet.cells(tbf.RecordCount + 1, i + 1)).

    ho eliminato la riga vuota ma per quanto alla faccenda dei fogli non ho risolto...

    ho testato la tua routina ma non esporta nulla....

    ora ceno e poi ci torno su...

    non copio la funzione del fielType...quella per forza funzia...l'ha elaborata un MVP..! ;-)

    ciao, Sandro.

    Option Compare Database

     Option Explicit

    Private Const StrPath As String = "C:\TuoPathXls\tuoFile.xlsx" ' da modifcare TuoPathXls e tuoFile

    Sub tabelleToXls2()

    Dim tbf As DAO.TableDef

     Dim newWorkBook As Object, newWorkSheet As Object, newExcelIstance As Object, rRange As Object

     Dim rst As DAO.Recordset

     Dim strSql As String

     Dim i As Integer

     Set newExcelIstance = CreateObject("Excel.application")

     Set newWorkBook = newExcelIstance.Workbooks.add

    For Each tbf In CurrentDb.TableDefs

          If (tbf.Attributes And dbSystemObject) Then

              Else

                  'Debug.Print tbf.Name

                     Set newWorkSheet = newWorkBook.Worksheets.add

                     newWorkSheet.Name = tbf.Name

                  For i = 0 To tbf.Fields.Count - 1

                      newWorkSheet.cells(1, i + 1) = tbf.Fields(i).Name

                      strSql = "select [" & tbf.Fields(i).Name & "] from [" & tbf.Name & "]"

                      Set rRange = newWorkSheet.Range(newWorkSheet.cells(2, i + 1), newWorkSheet.cells(tbf.RecordCount + 1, i + 1))

                      Select Case FieldTypeName(tbf.Fields(i))

                             Case "Date/Time"

                                 rRange.NumberFormat = "mm/dd/yyyy"

                             Case "Currency"

                                 rRange.NumberFormat = "$ #,##0.00"

                             Case "Single", "Double"

                                  rRange.NumberFormat = "#,##0.00"

                     End Select

                      rRange.CopyFromRecordset DBEngine(0)(0).OpenRecordset(strSql, dbOpenDynaset)

                 Next

                  newWorkSheet.cells.EntireColumn.AutoFit

          End If

      Next

     ' newExcelIstance.Visible = True

    ' For i = 1 To 3

    '      newWorkBook.Sheets("foglio" & i).Delete

    ' Next

      newWorkBook.Close SaveChanges:=True, fileName:=StrPath

      MsgBox "file xls con tutte le tabelle in " & StrPath, vbInformation, "Informazione"

     Set tbf = Nothing

      Set newExcelIstance = Nothing

      Set newWorkBook = Nothing

      Set newWorkSheet = Nothing

    End Sub

    La risposta è stata utile?

    0 commenti
  4. Anonimo
    2015-03-19T15:56:39+00:00

    Ma allora non hai nemmeno guardato il mio codice. :-(

    La risposta è stata utile?

    0 commenti