esportare tabelle da access in excel

Anonimo

Ho una serie di tabelle in access e vorrei esportarle tutte in un unico file Excel (cartella Excel con all'interno i vari fogli che corrisponderanno alle tabelle di cui sopra)... l'unica cosa che riesco ad ottenere è che viene trasferita sempre e solo il primo foglio della mia cartella di lavoro...

di seguito il codice che utilizzo:

Function Esporto() DoCmd.TransferSpreadsheet acExport, 8, "Lun", "C:\Documents and Settings\All Users\Desktop\Validazione\validazione.xls", False, "B1:o12000" False, "B1:o12000"Set xl = CreateObject("Excel.Application") ' dove sSource = path completo del tuo file .xls sSource = "C:\Documents and Settings\All Users\Desktop\Validazione\validazione.xls"With xl ' .Workbooks.Add .Workbooks.Open sSource ' .Sheets(sSheet).Activate .Visible = True End With End Function

nel mio caso la cartella è "validazione.xls" ed i fogli di lavoro sono divisi per giorni della settimana (lun, mar, ecc

Domanda bloccata. Questa domanda è stata eseguita dalla community del supporto tecnico Microsoft. È possibile votare se è utile, ma non è possibile aggiungere commenti o risposte o seguire la domanda.

0 commenti

Risposta accettata dall'autore della domanda

Anonimo

Ciao Sandro!

Posto di nuovo il codice perché ho l'impressione che non ci siamo capiti riguardo la posizione dei due ScreenUpdating. Se sbaglio, scusami.

Option Compare Database

Option Explicit

#Const DevMode = 0

Public Sub Test4()

Const cstrProc = "Test4"

On Error GoTo ErrH

Dim e As Long

' --- Personalizzare -------------------- >

Const cstrXlsFullPath = "D:\Percorso\Test1"

Const cblnShow = False

' --------------------------------------- <

Const cstrXlClass = "Excel.Application"

Const cstrFullName = "<FullName>"

Const cstrCnn = "OLEDB;Provider=Microsoft.ACE.OLEDB.12.0" _

& ";Data Source=" & cstrFullName _

& ";Mode=Read;"

Dim dbp As Access.CurrentProject

Dim dbs As DAO.Database

Dim tdf As DAO.TableDef

#If DevMode Then

Dim xlApp As Excel.Application

Dim xlWbk As Excel.Workbook

Dim xlWsh As Excel.Worksheet

Dim xlQry As Excel.QueryTable

#Else

Const xlCmdTable = 3

Dim xlApp As Object

Dim xlWbk As Object

Dim xlWsh As Object

Dim xlQry As Object

#End If

Dim blnNotRunning As Boolean

Dim strCnn As String

Dim strTable As String

Dim lngTable As Long

With Application

Set dbp = .CurrentProject

Set dbs = .CurrentDb

End With

strCnn = Replace(cstrCnn, cstrFullName, dbp.FullName)

Debug.Print strCnn

On Error Resume Next

Set xlApp = GetObject(Class:=cstrXlClass)

e = Err.Number

On Error GoTo ErrH

If e Then

blnNotRunning = True

Set xlApp = CreateObject(Class:=cstrXlClass)

End If

With xlApp

If blnNotRunning And cblnShow Then .Visible = True

.ScreenUpdating = False

Set xlWbk = .Workbooks.Add

End With

With xlWbk.Worksheets

.Add Count:=GetTableDefsCount(dbs) - .Count

End With

For Each tdf In dbs.TableDefs

If (tdf.Attributes And dbSystemObject) = False Then

lngTable = lngTable + 1

strTable = tdf.Name

Set xlWsh = xlWbk.Worksheets.Item(lngTable)

With xlWsh

.Name = strTable

Set xlQry = .QueryTables.Add(Connection:=strCnn _

, Destination:=.Range("A1"))

End With

With xlQry

.CommandType = xlCmdTable

.CommandText = strTable

.AdjustColumnWidth = True

.FieldNames = True

.Refresh

.Delete

End With

Set xlQry = Nothing

End If

MsgBox "Fatto!"

ExtP:

On Error Resume Next

Set tdf = Nothing

Set dbs = Nothing

Set dbp = Nothing

With xlApp

.ScreenUpdating = True

.DisplayAlerts = False

End With

xlWbk.Close SaveChanges:=True _

, FileName:=cstrXlsFullPath

If cblnShow Then

xlApp.Visible = True

Else

If blnNotRunning Then xlApp.Quit

End If

Set xlQry = Nothing

Set xlWsh = Nothing

Set xlWbk = Nothing

Set xlApp = Nothing

Exit Sub

ErrH:

With Err

MsgBox "ERR#" & CStr(.Number) _

& vbNewLine & .Description _

, vbOKOnly Or vbCritical, cstrProc

End With

Resume ExtP

End Sub

0 commenti

42 risposte aggiuntive

Anonimo

2015-03-24T18:58:52+00:00

ciao Maurizio, buona sera a te.

avevo interpretato male il tuo suggerimento di ieri, hai intuito correttamente :-)

Ora tutto è molto più chiaro.

Ringrazio io te tantissimo, mi hai dato modo per iniziare ad approfondire il tema automazione.

Ero già per certi aspetti soddisfatto per quanto ero riuscito ad ottenere con il mio codice iniziale, carente sotto molti punti di vista e migliorato in seguito ai tuoi consigli, ma la strada da seguire è quella che mi/ci hai mostrato negli ultimi posts.

Confermo ancora una volta che mi hai davvero stupito con le tue risposte e la tua soluzione finale.

Complimenti davvero per la preparazione.

Grazie, grazie e ancora grazie!

Ciao Maurizio, buona serata ;-)

Sandro.
La risposta è stata utile?

0 commenti Nessun commento
Anonimo

2015-03-24T17:13:06+00:00

Grazie a te, Sandro, dell'utilissimo scambio.
La risposta è stata utile?

0 commenti Nessun commento
Anonimo

2015-03-23T19:01:00+00:00

ciao Maurizio,

potentissimo l'oggetto QueryTables, in un colpo solo esporti intestazione campi e records...

mantenendo la formattazione....

altro che stare li ad esportare un campo alla volta...! ed in seguito formattarlo...!

ottima soluzione...!

Inoltre anche il codice risulta più rigoroso e pulito...! a tutto vantaggio dell'efficienza dell'intero processo.

chapeau Maurizio!

grazie ancora!

Sandro.
La risposta è stata utile?

0 commenti Nessun commento
Anonimo

2015-03-23T18:16:13+00:00

ciao Maurizio,

ho modificato da cosi :

With xlApp

      If blnNotRunning And cblnShow Then .Visible = True

      .ScreenUpdating = False               ' <---------

      Set xlWbk = .Workbooks.Add

    End With

a così : ( lasciando il settaggio del workbook)

With xlApp

      .ScreenUpdating = True                ' <---------

      .DisplayAlerts = False

      Set xlWbk = .Workbooks.Add

    End With

un centinaio abbondante di millesecondi ancora più performante...!

Grande...!!!

ciao, Sandro.
La risposta è stata utile?

0 commenti Nessun commento