Oltre a un Array di fogli aggiungere un altro foglio indipendente dall'array

Anonimo
2014-05-11T20:23:52+00:00

Ciao a tutti, ho bisogno di voi per sistemare un codice che utilizzo ormai da diverso tempo. L’ho scaricato dal sito di Mauro e riguarda un Array di fogli.Il codice è il seguente:Public Sub m()

    Dim shArray As Sheets

    Dim sh As Worksheet

On Error GoTo RigaErrore

    Set shArray = ThisWorkbook.Worksheets(Array("Foglio1", "Foglio2")

    For Each sh In shArray

        '...

        'codice da eseguire riguarda 5 TextBox. Quello che segue è un esempio di quello che viene eseguito

If TextBox1.Value > 0 Then

       .Range("A" & lRiga).Value = "=Archivio!C7"

       lRiga = lRiga + 1

Dopo questa riga quello che devo aggiungere è che il contenuto della textbox1 mi finisca nel foglio Archivio alla cella B10

A seguire se la textbox2, 3, 4 o 5 contiene un valore numerico mi riporterà il valore non solo nell’array che include 5 fogli ma anche nel foglio Archivio nella cella B11 per la textbox2, B12 texybox3 B14 textbox4 e B15 textbox15.

  End If    

Next

RigaChiusura:

    'Set a Nothing delle variabili oggetto

    Set shArray = Nothing

    Set sh = Nothing

    'uscita dalla routine

    Exit Sub

    RigaErrore:

    'mostro una MsgBox con i dati dell'errore

    MsgBox Err.Number & vbNewLine & Err.Description

    'vado alla riga di chiusura

    Resume RigaChiusura

End Sub

La mia necessità è quello di aggiungere in questo codice la possibilità di riportare su un foglio di nome archivio che non fa parte dell’array dati necessari in base a alle condizioni suindicate. Grazie

Microsoft 365 e Office | Excel | Per la casa | Windows

Domanda bloccata. Questa domanda è stata eseguita dalla community del supporto tecnico Microsoft. È possibile votare se è utile, ma non è possibile aggiungere commenti o risposte o seguire la domanda.

0 commenti Nessun commento
Risposta accettata dall'autore della domanda
Anonimo
2014-05-14T12:07:29+00:00

Ciao Geacs,

Hai fatto esattamente quello che ti ho chiesto, anzi molto di più tanto che mangiando mangiando ti viene l’appetito. Ho pensato di utilizzare il codice postato anche su un’altra cartella. 

Potrebbe essere necessario esercitare una certa attenzione, perché mentre ho cercato di rendere il codice generico, potrebbe richiedere qualche 'sintonizzazione' per affrontare uno scenario diverso. In caso di necessità, chiedi pure!

Se non ti chiedo troppo, potresti fare in modo che nella colonna A una volta copiati i collegamenti delle textbox che contengono i valori numerici del foglio archivio possa completarsi dalla cella A10 fino alla cella A25 senza andare oltre, riportando i collegamenti che trova sullo stesso foglio dalle colonne D ed E? 

Spero che io abbia capito anche se ancora lo scopo non é chiaro!

Inoltre ho notato che se dovessi inserire numeri decimali me li sposta sulla sinistra. Potresti correggere il codice in modo da farli rimanere sempre sulla destra?

Fatto!

Prova a sostituire la seconda versione del mio codice con:

'=========>>

Option Explicit

'--------->>

Private Sub CommandButton1_Click()

    Dim WB As Workbook

    Dim SH As Worksheet, aSH As Worksheet

    Dim Rng As Range, Rng2 As Range, Rng3 As Range

    Dim arrTBox As Variant

    Dim arrFogli As Variant

    Dim arrIn As Variant, arrOut() As Variant

    Dim vVal As Variant

    Dim i As Long, j As Long, k As Long, p As Long, x As Long

    Dim iRow As Long

    Const mySheets As String = "Foglio1,Foglio2,Foglio3,Foglio4,Foglio5" '<<==== Modifica

    Const sSheet As String = "Archivio"                                                      '<<==== Modifica

    Const primaRiga As Long = 10 '<<==== Modifica

    Const nonOltre As String = "A25"                                                        '<<==== Modifica

    arrFogli = Split(mySheets, ",")

    Set WB = ThisWorkbook

    Set aSH = WB.Sheets(sSheet)

    Set Rng = aSH.Range("D7")

    With Me

        arrTBox = Array(.TextBox1, .TextBox2, .TextBox3, .TextBox4, .TextBox5)

    End With

    iRow = primaRiga - 1

    For j = LBound(arrFogli) To UBound(arrFogli)

        Set SH = WB.Sheets(Trim(arrFogli(j)))

        With SH

            Set Rng2 = .Range("A" & iRow + 1, nonOltre)

            Rng2.ClearContents

        End With

    Next j

    k = Rng.Row

    For i = LBound(arrTBox) To UBound(arrTBox)

        vVal = arrTBox(i).Value

        If IsNumeric(vVal) And vVal > 0 Then

            Rng.Cells(i + 1).Value = CDbl(vVal)

            iRow = iRow + 1

            For j = LBound(arrFogli) To UBound(arrFogli)

                Set SH = WB.Sheets(Trim(arrFogli(j)))

                With SH

                    .Range("A" & iRow).Value = "=Archivio!C" & k + i

                    .Range("A" & iRow + 1).Value = "=Archivio!D" & k + i

                End With

            Next j

        Else

            iRow = iRow - 1

        End If

        iRow = iRow + 1

    Next i

    For i = LBound(arrFogli) To UBound(arrFogli)

        j = 0

        k = 0

        p = 0

        Set SH = WB.Sheets(Trim(arrFogli(i)))

        With SH

            x = .Range(nonOltre).Row - iRow

            Set Rng3 = .Range("D" & .Rows.Count).End(xlUp)

            Set Rng3 = .Range(Rng3, Rng3.End(xlUp)).Resize(x \ 2, 2)

            arrIn = Rng3.Value

            j = UBound(arrIn, 1)

            ReDim arrOut(1 To j * 2)

            For k = 1 To j

                p = p + 2

                arrOut(p - 1) = "=" & Rng3.Cells(k, 1).Address

                arrOut(p) = "=" & Rng3.Cells(k, 2).Address

            Next k

            .Range("A" & iRow + 1).Resize(j * 2).Value = Application.Transpose(arrOut)

        End With

    Next i

End Sub

'<<=========

===

Regards,

Norman

La risposta è stata utile?

0 commenti Nessun commento

20 risposte aggiuntive

Ordina per: Più utili
  1. Anonimo
    2014-05-12T14:29:38+00:00

    Ciao Geacs,

    Forse, potresti modificare il tuo codice così:

    '==========>>

    Option Explicit

    '--------->>

    Private Sub CommandButton1_Click()

        Dim lRiga As Long

        lRiga = 1

        With ActiveSheet

            If IsNumeric(TextBox1.Value) And TextBox1.Value > 0 Then

                .Range("A" & lRiga).Value = "=Archivio!C7"

                lRiga = lRiga + 1

                .Range("A" & lRiga).Value = "=Archivio!D7"

                lRiga = lRiga + 1

            End If

            If IsNumeric(TextBox2.Value) And TextBox2.Value > 0 Then

                .Range("A" & lRiga).Value = "=Archivio!C8"

                lRiga = lRiga + 1

                .Range("A" & lRiga).Value = "=Archivio!D8"

                lRiga = lRiga + 1

            End If

            If IsNumeric(TextBox3.Value) And TextBox3.Value > 0 Then

                .Range("A" & lRiga).Value = "=Archivio!C9"

                lRiga = lRiga + 1

                .Range("A" & lRiga).Value = "=Archivio!D9"

                lRiga = lRiga + 1

            End If

            If IsNumeric(TextBox4.Value) And TextBox4.Value > 0 Then

                .Range("A" & lRiga).Value = "=Archivio!C10"

                lRiga = lRiga + 1

                .Range("A" & lRiga).Value = "=Archivio!D10"

                lRiga = lRiga + 1

            End If

            If IsNumeric(TextBox5.Value) And TextBox5.Value > 0 Then

                .Range("A" & lRiga).Value = "=Archivio!C11"

                lRiga = lRiga + 1

                .Range("A" & lRiga).Value = "=Archivio!D11"

                lRiga = lRiga + 1

            End If

        End With

    End Sub

    '<<=========

    Tuttavia, verifica che questo codice inserisce la formula desiderata nelle celle di destinazione corrette nel caso in cui uno o più delle caselle di testo non hanno un valore numerico! 

    ===

    Regards,

    Norman

    La risposta è stata utile?

    0 commenti Nessun commento
  2. Anonimo
    2014-05-12T13:23:37+00:00

    Ciao Norman,

    Inutile dirti che è un capolavoro il codice postato  e fa esattamente quello che chiedevo.

    Prima di concludere, devi aiutarmi nella correzione di quello che sto già usando. Nell'array dei cinque fogli deve copiarmi se trova un valore numerico nelle textbox quello che segue:

    If TextBox1.Value > 0 Then
    
           .Range("A" & lRiga).Value = "=Archivio!C7"
    
           lRiga = lRiga + 1      .Range("A" & lRiga).Value = "=Archivio!D7"       lRiga = lRiga + 1end ifIf TextBox2.Value > 0 Then       .Range("A" & lRiga).Value = "=Archivio!C8"       lRiga = lRiga + 1      .Range("A" & lRiga).Value = "=Archivio!D8"       lRiga = lRiga + 1end ifIf TextBox3.Value > 0 Then       .Range("A" & lRiga).Value = "=Archivio!C9"       lRiga = lRiga + 1      .Range("A" & lRiga).Value = "=Archivio!D9"       lRiga = lRiga + 1end ifIf TextBox4.Value > 0 Then       .Range("A" & lRiga).Value = "=Archivio!C10"       lRiga = lRiga + 1      .Range("A" & lRiga).Value = "=Archivio!D10"       lRiga = lRiga + 1end ifIf TextBox5.Value > 0 Then       .Range("A" & lRiga).Value = "=Archivio!C11"       lRiga = lRiga + 1      .Range("A" & lRiga).Value = "=Archivio!D11"       lRiga = lRiga + 1end ifI collegamenti alle celle riportate viene copiato, solo che lo fa anche quando nella textbox non c'è nessun valore numerico. Invece deve riportare il collegamento solo se la textbox ha un valore numerico. Grazie
    

    La risposta è stata utile?

    0 commenti Nessun commento
  3. Anonimo
    2014-05-12T08:20:48+00:00

    Ciao Geacs,

    Visto  la condizione, che mi è sfuggita, che i TextBox debbano contenere un valore numerico, meglio sarebbe:

    '==========>>

    Option Explicit

    '--------->>

    Private Sub CommandButton1_Click()

        Dim arrTBox As Variant

        Dim SH As Worksheet

        Dim Rng As Range

        Dim i As Long

        Set SH = ThisWorkbook.Sheets("Archivio")

        Set Rng = SH.Range("B11")

        With Me

            arrTBox = Array(.TextBox1, .TextBox2, .TextBox3, .TextBox4, .TextBox5)

        End With

        For i = LBound(arrTBox) To UBound(arrTBox)

            If IsNumeric(arrTBox(i).Value) Then

                Rng.Cells(i + 1).Value = arrTBox(i).Value

            End If

        Next i

    End Sub

    '<<=========

    ===

    Regards,

    Norman

    La risposta è stata utile?

    0 commenti Nessun commento
  4. Anonimo
    2014-05-12T08:09:57+00:00

    Ciao Geacs,

    Prova qualcosa del genere:

    '==========>>

    Option Explicit

    '--------->>

    Private Sub CommandButton1_Click()

        Dim arrTBox As Variant

        Dim SH As Worksheet

        Dim Rng As Range

        Dim i As Long

        Set SH = ThisWorkbook.Sheets("Archivio")

        Set Rng = SH.Range("B11")

        With Me

            arrTBox = Array(.TextBox1, .TextBox2, .TextBox3, .TextBox4, .TextBox5)

        End With

        For i = LBound(arrTBox) To UBound(arrTBox)

            Rng.Cells(i + 1).Value = arrTBox(i).Value

        Next i

    End Sub

    '<<=========

    ===

    Regards,

    Norman

    La risposta è stata utile?

    0 commenti Nessun commento