Propriétés d'un fichier jpg sous EXIF 2.30 (géolocalisation)

Anonyme
2013-10-08T19:49:46+00:00

Bonjour le forum,

Permettez-moi de revenir sur un sujet que j’ai déjà abordé. Il s’agit de la lecture des propriétés appliquée à un fichier jpg.

Pour lire ces propriétés et en afficher les valeurs dans une feuille de calcul, j’utilise la routine ci-dessous.

Tant que le fichier utilise un protocole EXIF < =230, je retrouve les données souhaitées.

Par contre, dans le cas du protocole EXIF 230 qui reprend, e.a. la géolocalisation, je ne retrouve pas cette dernière dans les informations lues par la routine ci-dessous alors qu’elles sont bien présentes dans le détail des propriétés du fichier (clic droit dans l’explorateur).

Un membre du forum pourrait-il me suggérer l’une ou l’autre piste pour résoudre ce problème en VBA (Excel 2010 64 bits).

D’avance merci pour votre aide.

GiHem

Sub Macro3()

 Dim det_Headers(300)

Set objShell = CreateObject("Shell.Application")

Set objfolder = objShell.Namespace("C:\Users\azerty")

Workbooks(1).Sheets(2).Activate

For i = 0 To 300

 det_Headers(i) = objfolder.GetDetailsOf(objfolder.Items, i)

ActiveSheet.Cells(1, i + 1) = det_Headers(i)

Next

Workbooks(1).Sheets(2).Activate

j = 2

For Each strFileName In objfolder.Items

 For i = 0 To 300

Sheets(2).Cells(j, i + 1).Value = objfolder.GetDetailsOf(strFileName, i)

 Next

  j = j + 1

Next

End Sub

Microsoft 365 et Office | Excel | Pour la maison | Windows

Question verrouillée. Cette question a été migrée à partir de la Communauté Support Microsoft. Vous pouvez voter pour indiquer si elle est utile, mais vous ne pouvez pas ajouter de commentaires ou de réponses ni suivre la question.

0 commentaires Aucun commentaire
Réponse acceptée par l’auteur de la question
Anonyme
2014-09-25T23:38:30+00:00

Tu dois d'abord faire un relevé des numéros des champs qui t'intéressent. Essaie ceci :

Sub Macro3()

Dim Arr(), Elt As Variant, i As Long

Dim det_Headers(0 To 7), X As String

'La liste des numéros de champs dont tu veux extraire la valeur

 Arr = Array(0, 1, 20, 31, 166, 167, 168, 169)

Set objShell = CreateObject("Shell.Application")

'Adapte le chemin du répertoire où se retrouvent les photos

Set objfolder = objShell.Namespace("C:\Users\Ton profil\Pictures\Roxio Échantillons 3D")

Application.ScreenUpdating = False

 Application.EnableEvents = False

With ThisWorkbook

     With .Sheets("Feuil1") 'Adapte le nom de la feuille

         .Activate

         For Each Elt In Arr

             det_Headers(i) = objfolder.GetDetailsOf(objfolder.Items, Elt)

             .Cells(1, i + 1) = det_Headers(i)

             i = i + 1

         Next

        j = 2: i = 0

        For Each strFileName In objfolder.Items

             For Each Elt In Arr

                 Select Case Elt

                     'Tu entres tous les numéros des champs qui ont une valeur numérique

                     Case 1, 166 To 169 'pour les données numériques

                         X = objfolder.GetDetailsOf(strFileName, Elt)

                         If Not IsNumeric(Left(X, 1)) Then

                            X = Right(X, Len(X) - 1)

                         End If

                         .Cells(j, i + 1).Value = Val(Replace(Trim(X), ",", "."))

                     Case Else

                         .Cells(j, i + 1).Value = Trim(objfolder.GetDetailsOf(strFileName, Elt))

                 End Select

                 i = i + 1

             Next

             j = j + 1: i = 0

         Next

         .UsedRange.EntireColumn.AutoFit

     End With

 End With

Application.ScreenUpdating = True

Application.EnableEvents = True

End Sub

Cette réponse a-t-elle été utile ?

0 commentaires Aucun commentaire

32 réponses supplémentaires

Trier par : Les plus récents
  1. Anonyme
    2014-10-02T09:03:05+00:00

    MichD,

    Tout fonctionne bien, merci beaucoup

    Est-il possible d'insérer une ligne de code pour qu'il y ai un lien HyperText sur le nom du fichier ?

    Bonne journée

    Cette réponse a-t-elle été utile ?

    0 commentaires Aucun commentaire
  2. Anonyme
    2014-09-26T13:30:04+00:00

    En relisant ce commentaire :

    un p'tit truc bizarre code 31 (dimension), ca me donne que la largeur et non L x H

    Une petite explication :

    Dans cette ligne de code :  .Cells(j, i + 1).Value = Val(Replace(Trim(X), ",", "."))

    Une des caractéristiqus  de la fonction VAL() est qu'il transforme le contenu "numérique" d'une variable "TEXTE" en valeur numérique. Pour ce faire, la valeur numérique doit être située au tout début de la chaîne de caractères. Dès qu'il rencontre un caractère qui n'est pas du numérique, il ne tient plus compte du reste de la chaîne de caractères. De plus, le séparateur décimal doit être absolument le point.

    Exemple :

    Val("123toto")  = 123

    Val("25,10 xxx") = 25

    Val("145.236dfaa")= 145.236

    Dans ton cas, le champ utilise le "X" entre la largeur et la hauteur. Par conséquent, la fonction Val() ne tient pas compte du reste de la chaîne de caractères à partir du "X"

    Tu dois sortir de champ de cette section du Select Case

    Cette réponse a-t-elle été utile ?

    0 commentaires Aucun commentaire
  3. Anonyme
    2014-09-26T09:21:58+00:00

    Un fichier exemple avec les numéros de champs avec le résultat obtenu sous Windows 8.1  et Excel 2013  http://cjoint.com/?DIAlwQ0kgtx 

    Comme ceci pour choisir le répertoire dans une fenêtre...

    '------------------------------------------------------------------

    Sub Macro3()

    Dim Arr(), Elt As Variant, i As Long

    Dim det_Headers(0 To 7), X As String

    Dim Répertoire As String

    'Si tu veux que la fenêtre pour choisir le répertoire s'ouvre

    'par défaut dans un chemin particulier, tu renseignes cette variable

    'Si ce répertoire n'existe pas, la fenêtre s'ouvrira dans le répertoire courant.

    Répertoire = "C:\Users\Ton profil\Pictures\Roxio Échantillons 3D"

    Répertoire = SelDossier(Répertoire)

    If Répertoire = "" Then MsgBox "Opération annulée.": Exit Sub

    'La liste des numéros de champs dont tu veux extraire la valeur

     Arr = Array(0, 1, 20, 31, 166, 167, 168, 169)

    Set objShell = CreateObject("Shell.Application")

    Set objfolder = objShell.Namespace(CStr(Répertoire))

    Application.ScreenUpdating = False

     Application.EnableEvents = False

    With ThisWorkbook

         With .Sheets("Feuil1") 'Adapte le nom de la feuille

             .Activate

             For Each Elt In Arr

                 det_Headers(i) = objfolder.GetDetailsOf(objfolder.Items, Elt)

                 .Cells(1, i + 1) = det_Headers(i)

                 i = i + 1

             Next

            j = 2: i = 0

            For Each strFileName In objfolder.Items

                 For Each Elt In Arr

                     Select Case Elt

                         'Tu entres tous les numéros des champs qui ont une valeur numérique

                         Case 1, 166 To 169 'pour les données numériques

                             X = objfolder.GetDetailsOf(strFileName, Elt)

                             If Not IsNumeric(Left(X, 1)) Then

                                X = Right(X, Len(X) - 1)

                             End If

                             .Cells(j, i + 1).Value = Val(Replace(Trim(X), ",", "."))

                         Case Else

                             .Cells(j, i + 1).Value = Trim(objfolder.GetDetailsOf(strFileName, Elt))

                     End Select

                     i = i + 1

                 Next

                 j = j + 1: i = 0

             Next

             .UsedRange.EntireColumn.AutoFit

         End With

     End With

    Application.ScreenUpdating = True

    Application.EnableEvents = True

    End Sub

    '------------------------------------------------------------------

    Function SelDossier(Defaut As String)

    Dim FD As FileDialog

    Set FD = Application.FileDialog(msoFileDialogFolderPicker)

    With FD

        .InitialFileName = Defaut

        If .Show = -1 Then

            SelDossier = FD.SelectedItems(1)

        End If

    End With

    Set FD = Nothing

    End Function

    '------------------------------------------------------------------

    Cette réponse a-t-elle été utile ?

    0 commentaires Aucun commentaire
  4. Anonyme
    2014-09-26T04:52:01+00:00

    Bonjour,

    C'est génial ;-)

    juste quelques petites modifs pour que ça marche chez moi

    Avec ces n°

    Arr = Array(0, 1, 20, 31, 160, 162, 161, 164)

    Case 1, 31, 162, 161, 164   'pour les données numériques

    un p'tit truc bizarre code 31 (dimension), ca me donne que la largeur et non L x H

    Si tu as le temps peux tu me dire comment faire pour choisir le répertoire sans le rentrer en dur ici :

    Set objfolder = objShell.Namespace("f:.....

    Encore merci pour ton implication et ton savoir

    Bonne journée

    Cette réponse a-t-elle été utile ?

    0 commentaires Aucun commentaire