Musik Charts mit Excel Ermitteln?

Ich bedenke mich für den sehr lehrreichen Excel Kurs in dem ich viel gelernt habe was ich auch auf andere Projekte anwenden kann.

Hallo Daniel,

es freut mich das ich helfen konnte. Und ich denke auch das einige aktuelle (oder spätere) Mitleser das eine oder andere gebrauchen können. Wärst Du bitte so nett und markierst diesen Post als Antwort und verteilst ggf. noch ein Rating auf die Posts die Dir geholfen haben?

Damit können wir sicherstellen das die ganze Arbeit noch einige Zeit verfügbar bleibt, ansonsten könnte das alles beim nächsten Cleanup gelöscht werden.

Vielen Dank, Andreas.

Ich habe jetzt noch die Letzten Kleinigkeiten angepasst und bis 2030 die Charts in der Gleichen Arbeitsmappe mit einem Übersichts Tabellenblatt eingerichtet die PT muss ich zwar Jedes Jahr neu erstellten aber das ist kein Problem.

Ich bedenke mich für den sehr lehrreichen Excel Kurs in dem ich viel gelernt habe was ich auch auf andere Projekte anwenden kann.

um die +/- eines Songs auszuwerten wollte ich noch wissen ob man auch auswerten kann um wieviel Plätze sich ein Song verbessert bzw. verschlechtert hat.

Hmm? Hast Du doch schon vor der Nase, statt

=VORZEICHEN(WENNFEHLER(MITTELWERTWENNS([Platz];[Titel];[@Titel];[KW];[@KW]-1);0) - WENNFEHLER(MITTELWERTWENNS([Platz];[Titel];[@Titel];[KW];[@KW]);0))

einfach VORZEICHEN weglassen.

=(WENNFEHLER(MITTELWERTWENNS([Platz];[Titel];[@Titel];[KW];[@KW]-1);0) - WENNFEHLER(MITTELWERTWENNS([Platz];[Titel];[@Titel];[KW];[@KW]);0))

Dann musst Du jedoch die bedingte Formatierung anpassen, der Typ steht auf Prozent und bei den tatsächlichen Werten kommen da andere Symbole... logisch!? Mach irgendwas wie Zahl >=1.

Andreas.

Ich habe jetzt noch mal an der Tabelle ein bisschen herumgebastelt:

✔️Das 1.Blatt Bewertet die Schlager-Charts

✔️Das 2.Blatt bewertet die Pop Charts

✔️im 3.Blatt ist Power Query Für die Pop Charts eingerichtet

✖️für die Schlager-Charts würde ich es auch gerne verwenden das Problem ist aber das die Quellen keine Tabellen enthalten.

Zu 3.

mit der gefälschten Formel werden in den Top 10 jetzt auch nur 10 Songs angezeigt den Punkt können wir jetzt auch.✔️

Zu Ps.

Die PT habe ich jetzt mit der KW bzw. min./max. Platzierung ergänzt.✔️

um die +/- eines Songs auszuwerten wollte ich noch wissen ob man auch auswerten kann um wieviel Plätze sich ein Song verbessert bzw. verschlechtert hat.

Ps. die Sortierer die ich Farblich hervorgehoben habe sind nur für eine bessere Übersicht und werden nicht zum filtern verwendet mir wäre natürlich zum Abschluss noch am liebsten das ich über ein Dropdown Menü einfach nur pro Auswertungsblatt das nächste Jahr auswähle & eine neue Auswertung starte aber da das wahrscheinlich nicht möglich ist werde ich die bestehenden Tabellen fortführen & filtern bzw. für jedes Jahr ein eigenes Blatt verwenden.

Zu 2.
Formatiere die KW-Spalte als Standard (nicht als Datum), dann siehst Du die Nummern 1-52 in der Spalte und kannst auch danach filtern.

Zu 3.
Genau, traue nie einer Statistik die Du nicht selber gefälscht hast.
Bei jedem Turnier gibt es die Plätze 1,2,3 und wenn nun 2 Spieler den 1. Platz und 2 weitere Spieler den 2. Platz belegt haben, dann gibt es IMMER 2 Gold- und 2 Silbermedaillen.

Du kannst die Fälschung auch automatisieren, addiere zu der Bewertungsformel einfach eine kleine Zufallszahl.
L3: =10-[@Platz]*0,5+ZUFALLSZAHL()/10

Zu Ps.
a) wie lang ein Song in den Charts war bzw. was die beste und Schlechteste Platzierung
Um es zu verstehen: Mach mal eine neue PT ziehe den Titel in die Zeilen und KW in die Werte, bei Zahlen macht die PT immer eine Summe.
Klick in der PT mit rechts in die KW Spalte \ Werte zusammenfassen nach \ Anzahl
Zieh den Platz in die Werte \ Werte zusammenfassen nach \ Min
Zieh den Platz in die Werte \ Werte zusammenfassen nach \ Max

Das kannst Du natürlich auch so in Deiner Top10-PT machen.

b) Verbesserung bzw. Verschlechterung eines Songs
Da hast Du jetzt ein Problem weil die Daten nur für ein Jahr in der Tabelle sind.
In KW 1 müsstest Du ja auf die KW52 des letzten Jahres zugreifen, die hast Du nicht, also geht das in KW1 nicht.

Ansonsten ist es "relativ" einfach, Du brauchst ja nur die Differenz vom letztem zu diesem Platz.
Wenn der letzte 2 war und dieser 1, dann 2-1=1 also aufgestiegen, andersrum 1-2=-1 also abgestiegen.

Berücksichtigen wir die Quelle mal mit, dann ist es einfach:

Machen wir eine Spalte "Letzter Platz" hinzu mit dieser Formel
=SUMMEWENNS([Platz];[Titel];[@Titel];[Quelle];[@Quelle];[KW];[@KW]-1)

Machen wir noch eine Spalte "AufAb" hinzu
=VORZEICHEN([@LetzterPlatz]-[@Platz])
und wenden eine Bedingte Formatierung mit 3 Pfeil-Symbolsatz an, fertig.

Von der Quelle unabhängig ist das nicht so einfach, weil die Anzahl der Titel in einer Woche nicht mir der Anzahl der Titel in dieser Woche übereinstimmen müssen.
Um das zu rechnen brauchen wir den Mittelwert des Platzes eines jeden Titels in jeder KW.
=MITTELWERTWENNS([Platz];[Titel];[@Titel];[KW];[@KW]-1)
Das gibt jedoch einen Fehler zurück wenn der Titel in der Vorwoche nicht vorhanden ist. Also
=WENNFEHLER(MITTELWERTWENNS([Platz];[Titel];[@Titel];[KW];[@KW]-1);0)
und ebenso für diese Woche
=WENNFEHLER(MITTELWERTWENNS([Platz];[Titel];[@Titel];[KW];[@KW]);0)

Das können wir dann gleich kombinieren in unserer AufAb Spalte
=VORZEICHEN(WENNFEHLER(MITTELWERTWENNS([Platz];[Titel];[@Titel];[KW];[@KW]-1);0) - WENNFEHLER(MITTELWERTWENNS([Platz];[Titel];[@Titel];[KW];[@KW]);0))

Andreas.